#!/usr/bin/perl

use strict;   # mini.pl - modified Pratt parser by tybalt89
use warnings; # https://en.wikipedia.org/wiki/Pratt_parser
sub error { die "ERROR  ", s/\G/ <@_> /r, "\n" }

sub expr # two statement parser - precedences: (3 **) (2 * /) (1 + -)
  {
  my $answer =
    /\G\s* ((?:\d+(?:\.\d*)?|\.\d+)(e[+-]?\d+)?) /gcxi ? $1 :
    /\G\s*\(/gc ? (expr(0), /\G\s*\)/gc || error 'missing )')[0] :
    /\G\s* - /gcx ? -expr(3) :  # unary minus
    /\G\s* \+ /gcx ? +expr(3) :  # unary plus
    error 'bad operand';
  $answer =
    $_[0] <= 3 && /\G\s* \*\* /gcx ? $answer ** expr(3) :
    $_[0] <= 2 && /\G\s* \* /gcx   ? $answer * expr(3)  :
    $_[0] <= 2 && /\G\s* \/ /gcx   ? $answer / expr(3)  :
    $_[0] <= 1 && /\G\s* \+ /gcx   ? $answer + expr(2)  :
    $_[0] <= 1 && /\G\s* \- /gcx   ? $answer - expr(2)  :
    return $answer while 1;
  }

for ( @ARGV ? @ARGV : scalar <> ) # source as commandline args or stdin
  {
  my $answer = expr(0);
  /\G\s*\z/gc ? print s/\s*\z/ = $answer\n/r : error 'incomplete parse';
  }