use warnings;
use strict;
use DBI;

my $dbh = DBI->connect("dbi:SQLite:dbname=:memory:", undef, undef,
	{ RaiseError=>1, AutoCommit=>1 } );

$dbh->do(<<'ENDSQL');
CREATE TABLE Dummy_Test (
	Timestamp INTEGER PRIMARY KEY,
	Foo TEXT,
	Bar TEXT
);
ENDSQL
$dbh->do(<<'ENDSQL');
CREATE TRIGGER Dummy_Test_dupe BEFORE UPDATE ON Dummy_Test FOR EACH ROW
	WHEN ( OLD.Timestamp IS NEW.Timestamp AND OLD.Foo IS NEW.Foo AND OLD.Bar IS NEW.Bar )
	BEGIN SELECT RAISE(IGNORE); END;
ENDSQL
$dbh->do(<<'ENDSQL');
CREATE TRIGGER Dummy_Test_modify BEFORE UPDATE ON Dummy_Test FOR EACH ROW
	WHEN ( OLD.Foo IS NOT NEW.Foo OR OLD.Bar IS NOT NEW.Bar )
	BEGIN SELECT RAISE(ABORT, "same Timestamp but different values"); END;
ENDSQL

my $in = $dbh->prepare(<<'ENDSQL');
INSERT INTO Dummy_Test (Timestamp,Foo,Bar) VALUES (?,?,?)
	ON CONFLICT (Timestamp) DO UPDATE SET Foo=EXCLUDED.Foo, Bar=EXCLUDED.Bar;
ENDSQL

$in->execute(12345,'Hello','World');
$in->execute(12345,'Hello','World');
my $e;
eval { $in->execute(12345,'Hello','abcde'); 1 } or do { $e = $@ };
if ( defined $e ) { print "Third insert failed as expected: $e" }
else { die "Third insert didn't fail as expected" }