#!/usr/bin/perl
#
use strict;
use warnings;
use 5.010;
use Benchmark qw(cmpthese);

our @orig_array;
for (1 .. 1000) {push @orig_array, int rand 4}
say join ", ", @orig_array;

my $count = 10_000;
cmpthese($count, {
  anilmwr        => \&anilmwr,
  roboticus_1    => \&roboticus_1,
  roboticus_2    => \&roboticus_2,
  kennethk_1     => \&kennethk_1,
  kennethk_2     => \&kennethk_2,
  kennethk_3     => \&kennethk_3,
  Anonymous_Monk => \&Anonymous_Monk,
  SuicideJunkie  => \&SuicideJunkie,
  kcott          => \&kcott,
  GrandFather    => \&GrandFather,
  Cristoforo     => \&Cristoforo,
  dbuckhal       => \&dbuckhal,
});

sub anilmwr { # Fixed but keeping the concept of the original
    my @array = @main::orig_array;
    my @array1 = ();
    my @array2 = ();
    foreach my $i (@array) {
        push @array1, $i if $i == 0;
        push @array2, $i if $i != 0;
    }
    my @new_array = (@array1, @array2);
}

sub roboticus_1 {
    my @array = @main::orig_array;
    my @new_array=();
    for my $i (@array) {
        if ($i) {
            push @new_array, $i;
        }
        else {
            unshift @new_array, $i;
        }
    }
}

sub roboticus_2 {
    my @array = @main::orig_array;
    my @new_array = (
        grep( { ! $_ } @array),
        grep( { $_ } @array)
    );
}

sub kennethk_1 {
    my @array = @main::orig_array;
    @array = sort {-($a == 0) || $b == 0} @array;
}

sub kennethk_2 {
    my @array = @main::orig_array;
    @array = sort {($b == 0)-($a == 0)} @array;
}

sub kennethk_3 {
    my @array = @main::orig_array;
    @array = sort {!$b - !$a} @array;
}

# I do not have List::MoreUtils on this work machine, and can't install it now.
# A shame 'cos I had high hopes for this one. May try it at home later if the tuit
# is to be found
# use List::MoreUtils 'part';
# sub davido {
#    my @array = @main::orig_array;
#    @array = map { @$_ } part { !!$_ } @array;
# }

sub Anonymous_Monk {
    my @array = @main::orig_array;
    @array = do { my @tmp = grep $_, @array; ((0)x(@array-@tmp),@tmp) };
}

sub SuicideJunkie {
    my @array = @main::orig_array;
    my $size = @array;
    @array = grep {$_} @array;
    unshift @array, (0) x ($size - @array);
}

sub kcott {
    my @array = @main::orig_array;
    my $zeros = 0;
    @array = map { $_ == 0 ? ++$zeros && () : $_ } @array;
    unshift @array, (0) x $zeros;
}

sub GrandFather {
    my @array = @main::orig_array;
    my @newArray = grep{!$_} @array;
    push @newArray, grep {$_} @array;
}

sub Cristoforo {
    my @array = @main::orig_array;
    for my $i (0 .. $#array) {
        unshift @array, splice @array, $i, 1 if $array[$i] == 0;
    }
}

sub dbuckhal {
    my @array = @main::orig_array;
    my @y;
    for ( @array ) {
        ( $_ ) ? push @y, $_ : unshift @y, $_;
    }
}