#!/usr/bin/perl -w
use strict;

use XML::Twig;
my $twig=XML::Twig->new( pretty_print => 'indented')
                  ->parse( \*DATA);

my @ds= $twig->root->children( 'ds');

foreach my $attr (@ds) { 
    
    my $ds_elt= XML::Twig::Elt->new( 'ds');   # new XML::Twig::Elt is deprecated
    # to create the element as a child use 'last_child', not 'after'
    # you might want to use 'first_child' instead, I don't know your data 
    $ds_elt->paste( last_child => $attr);    # I like using => here
   
    my $unknown= "0";          
    my $unknown_elt= XML::Twig::Elt->new( unknown_sec => $unknown); 
    # you initially tried to paste $ds_elt again
    # I don't know where you want to paste the element but I guess it's here
    # you might also want to have a look at the insert method that creates
    # an element as the only child of the calling element, see
    # http://www.xmltwig.com/xmltwig/twig_dev.html#METHODS_XML_Twig_Elt_insert 
    $unknown_elt->paste( first_child => $ds_elt);     

    my $comment= " PDP Status ";          
    # this is how you create a comment: with an element name '#COMMENT'  
    my $comment_elt= XML::Twig::Elt->new( '#COMMENT' => $comment);
    # you could also write  $comment_elt->paste( last_child => $ds_elt);
    $comment_elt->paste( 'after', $unknown_elt);

    my $min= "NaN";          
    my $min_elt= XML::Twig::Elt->new( min => $min); 
    $min_elt->paste( after => $comment_elt);

}

$twig->print;

__DATA__
<doc>
  <ds><content/></ds>
  <ds><content/></ds>
</doc>