#!/usr/bin/perl
use warnings;
use strict;
use IO::Socket;
use threads;
$|++;

print $$;

my $server = new IO::Socket::INET(
    Timeout   => 7200,
    Proto     => "tcp",
    LocalPort => 12345,
    Reuse     => 1,
    Listen    => 2
);
my $num_of_client = -1;

while (1) {
    my $client;

    do {
        $client = $server->accept;
    } until ( defined($client) );

    my $peerhost = $client->peerhost();
    print "accepted a client $client, $peerhost, id = ", ++$num_of_client, "\n";

     #spawn  a thread here for each client
   my $thr = threads->new( \&processit,$client,$peerhost )->detach(); 

}

sub processit {
     my ($lclient,$lpeer) = @_; #local client
   
     if($lclient->connected){
          # Here you can do your stuff
          # I use have the server talk to the client
          # via print $client and while(<$lclient>)
          print $lclient "$lpeer->Welcome to server\n"; #and 
          #$lclient->recv;
          while(<$lclient>){print $lclient "$lpeer->$_\n"}
        
    }
  
  #close filehandle before detached thread dies out
  close( $lclient);
}
__END__

##</code><code>##

#!/usr/bin/perl
use warnings;
use strict;
use IO::Socket;
use threads;
use threads::shared;
$|++;
print "$$ Server started\n";;  # do a "top -p -H $$" to monitor server threads

our @clients : shared;
@clients = ();

my $server = new IO::Socket::INET(
    Timeout   => 7200,
    Proto     => "tcp",
    LocalPort => 12345,
    Reuse     => 1,
    Listen    => 3
);
my $num_of_client = -1;

while (1) {
    my $client;

    do {
        $client = $server->accept;
    } until ( defined($client) );

    my $peerhost = $client->peerhost();
    print "accepted a client $client, $peerhost, id = ", ++$num_of_client, "\n";
    my $fileno = fileno $client;
    push (@clients, $fileno);
    #spawn  a thread here for each client
    my $thr = threads->new( \&processit, $client, $fileno, $peerhost )->detach(); 
}
# end of main thread

sub processit {
     my ($lclient,$lfileno,$lpeer) = @_; #local client
        
     if($lclient->connected){
          # Here you can do your stuff
          # I use have the server talk to the client
          # via print $client and while(<$lclient>)
          print $lclient "$lpeer->Welcome to server\n";  
          
          while(<$lclient>){
             # print $lclient "$lpeer->$_\n";
              print "clients-> @clients\n";           
              
              foreach my $fn (@clients) { 
                  open my $fh, ">&=$fn" or warn $! and die;
                  print $fh  "$lpeer->$_"  
                  }
           
           }
        
    }
  
  #close filehandle before detached thread dies out
  close( $lclient);
  #remove multi-echo-clients from echo list
  @clients = grep {$_ !~ $lfileno} @clients;

}
__END__

##</code><code>##

#!/usr/bin/perl
use warnings;
use strict;
use Tk;
use IO::Socket;

require Tk::ROText;

#get id
my $name = shift || 'anon';

# create the socket
my $host = 'localhost';
my $port = 12345;

my $socket = IO::Socket::INET->new(
       PeerAddr => $host,
       PeerPort => $port,
       Proto    => 'tcp',
      );

defined $socket or die "ERROR: Can't connect to port $port on $host: $!\n";

print STDERR "Connected to server ...\n";

my $mw  = new MainWindow;
my $log = $mw->Scrolled('ROText',
           -scrollbars=>'ose',
           -height=> 5,
           -width=>45,
           -background => 'lightyellow',
           )->pack;

my $txt = $mw->Entry(
          -background=>'white',
          )->pack(-fill=> 'x', -pady=> 5);

$mw ->bind('<Any-Enter>' => sub { $txt->Tk::focus });
$txt->bind('<Return>' => [\&broadcast, $socket]);

$mw ->fileevent($socket, readable => sub {
                    my $line = <$socket>;
                      unless (defined $line) {
                       $mw->fileevent($socket => readable => '');
                       return;
                       }
         $log->insert(end => $line);
         $log->see('end');
  });


MainLoop;

sub broadcast {
    my ($ent, $sock) = @_;

    my $text = $ent->get;
    $ent->delete(qw/0 end/);

    print $sock $name.'->'. $text, "\n";
}
__END__