Use a hash with the gene names as keys. You can then put all the data in one structure,

my %gene = (
    gene_name_1 => { start=>'start_1', stop=>'stop_1', chr=>'chr_1'},
    # ...
);
[download]

Like everyone says--whenever you need to do a lookup in Perl: Think hashes,

#! perl -slw
use strict;
use Data::Dumper;

my @gene_score = (
         [ "gene_name_0", "score_0" ],
         [ "gene_name_1", "score_1" ],
#            ...
         [ "gene_name_400", "score_400" ]
);

my @gene_start_stop_chr = (
         [ "gene_name_0", "start_0", "stop_0", "chr_0" ],
         [ "gene_name_1", "start_1", "stop_1", "chr_1" ],
#            ...
          [ "gene_name_400", "start_400", "stop_400", "chr_400" ],
          [ "gene_name_30000", "start_30000", "stop_30000", "chr_30000
+" ]
);

## Build a hash from the lookup array
my %gene_start_stop_chr = map{ 
    $_->[ 0 ] => [ @{ $_ }[ 1 .. 3 ] ] 
} @gene_start_stop_chr;

## Use it to map the inputs to results
my @results = map{
    [ 
        $_->[ 0 ], 
        $_->[ 1 ], 
        @{ $gene_start_stop_chr{ $_->[ 0 ] } } 
    ]
} @gene_score;

print Dumper \@results;
__END__
P:\test>377857
$VAR1 = [
          [
            'gene_name_0',
            'score_0',
            'start_0',
            'stop_0',
            'chr_0'
          ],
          [
            'gene_name_1',
            'score_1',
            'start_1',
            'stop_1',
            'chr_1'
          ],
          [
            'gene_name_400',
            'score_400',
            'start_400',
            'stop_400',
            'chr_400'
          ]
        ];
[download]

I wrote something up, but Zaxo (and now rir) beat me to the punch, so instead here's some code to convert your arrays into a single hash:

my %gene = ();
foreach (@gene_score) {
  $gene{$_->[0]}->{score} = $_->[1];
}

foreach (@gssc) {
  $gene{$_->[0]}->{start} = $_->[1];
  $gene{$_->[0]}->{stop} = $_->[2];
  $gene{$_->[0]}->{chr} = $_->[3];
}
[download]

Now %gene looks like:

%gene = ( gene_name_0 => { score => 'score_0',
                           start => 'start_0',
                           stop  => 'stop_0',
                           chr   => 'chr_0' },
          gene_name_1 => { score => 'score_1',
          ...
        );
[download]

Brad

$, = " ";

# just playing with the =>'s

my @gn_score = (
    [ name_0 => score_0 => ],
    [ name_1 => score_1 => ],
    [ name_2 => score_2 => ],
);

my @gn_start_stop_chr = (
    [ name_0 => b_0 => e_0 => ],
    [ name_1 => b_1 => e_1 => ],
    [ name_2 => b_2 => e_2 => ],
    [ name_0 => b_30 => e_3 => ],
    [ name_2 => b_42=> e_4 => ],
    [ name_1 => b_51=> e_5 => ],
);

my %score;

$score{$_->[0]} = $_->[1] for (@gn_score );

for ( @gn_start_stop_chr) {
    my ( $name => $begin => $end => ) = @$_;
    die unless exists $score{$name};
    print $name,   # or stash your data somewhere
        $score{$name}, $begin, $end, $/;
};
[download]