http://qs1969.pair.com?node_id=794600

reasonablekeith has asked for the wisdom of the Perl Monks concerning the following question:

I'm trying to push some files around using a couple of perl scripts and sockets, but have come up against an intermittent problem reading and writing data. Simply, my server is doing a syswrite, but my client's sysread doesn't receive all the data.

The sockets are created in the normal way 

    my $sock = IO::Socket::INET->new(PeerAddr => '127.0.0.1',
                                         PeerPort => '9090',
                                         Proto    => 'tcp')
      or die("Couldn't connect: $!");

[download]
and 

    my $server = IO::Socket::INET->new( Proto     => 'tcp',
                                        LocalPort => $PORT,
                                        Listen    => 10,
                                        Reuse     => 0)
        or die("$!");

[download]
and my read / write functions look like this 
# server
sub write {
    my ($self, $string) = @_;
    my $server_socket = $self->{SERVER_SOCKET};

    my $write_length = sprintf "%020d", length($string);
    syswrite $server_socket, $write_length, 20;

    print "Writing $write_length bits of data\n";
    syswrite $server_socket, $string, $write_length;

}

# client
sub read {
    my ($self, $param) = @_;
    my $sock = $self->get_socket();

    my $read_length;
    my $buffer;
    sysread $sock, $read_length, 20;
    sysread $sock, $buffer, $read_length;

    my $buffer_length = length($buffer);
    $buffer_length == $read_length 
      or die("Tried to read $read_length bits but only got $buffer_len
+gth bits\n");

    return $buffer;
}

[download]
Which occasionally gives output like this. 
server
  ...
  Writing 00000000000000014848 bits of data

client
  
  Tried to read 00000000000000014848 bits but only got 13140 bits

[download]
The really weird thing is that most times this will just work. My client and server are running on the same machine, which has active perl 5.10, and IO::Socket::INET is at version 1.31.

Ignoring the code and it's limitations (which I'll work on if I get this sorted), does anyone see why this might be failing every now and then?

Thanks,

Rob

---
my name's not Keith, and I'm not reasonable.

Replies are listed 'Best First'.
Re: Missing data in IO::Socket::INET sysread/syswrite
by ikegami (Patriarch) on Sep 10, 2009 at 15:35 UTC
    So do a second read. Nothing guarantees you'll get the number of bytes you've requested. 
    use Carp qw( croak );

sub sysread_full
    my $fh               =  $_[0]
    our $buf; local *buf = \$_[1];  # alias
    my $to_read          =  $_[2]
    my $offset           =  $_[3] || 0;

    $offset += length($buf) if $offset < 0;
    croak("Offset outside string") if $offset < 0;

    my $tot_read = 0;
    while ($to_read > 0) {
        my $bytes_read =
            sysread($fh, $buf, $to_read, $offset+$tot_read);
        return undef     if !defined($bytes_read);
        return $tot_read if !$bytes_read;
        $to_read  -= $bytes_read;
        $tot_read += $bytes_read;
    }

    return $tot_read;
}


...
    sysread_full $sock, $read_length, 20;
    sysread_full $sock, $buffer, $read_length;
...

    [download]

    The behaviour I've observed follows: If there are bytes available to be read, they will be returned immediately, even if there are fewer than requested. (Users of select rely on this.) If there no bytes available to read, it will block.

    Update: Added code.
    Update: sysread_full differed from sysread in its handling of the offset. Fixed.

[reply]
[d/l]
[select]
      d'oh. I'd ass-u-me d that it blocked for the full length of the read. I just hacked in this for the read subroutine... 
          my $total_bytes_to_read;
    sysread $sock, $total_bytes_to_read, 20;

    my $total_bytes_read = 0;

    my $read_string = '';
    while ($total_bytes_read < $total_bytes_to_read) {
        my $buffer;
        my $bytes_read = sysread $sock, $buffer, ($total_bytes_to_read
+ - $total_bytes_read);
        $total_bytes_read += $bytes_read;
        $read_string .= $buffer;
    }

    $total_bytes_to_read == $total_bytes_read 
      or die("Tried to read $total_bytes_to_read bits but only got $to
+tal_bytes_read bits\n");

    return $read_string;

      [download]
      and have been unable to reproduce the error. Thank you! ++

      PS: I will abstract the loop, as I realise the other sysread here could suffer the same problem

      Update: Just seen your code. I shall be nicking that :)

      Update2: Worked a treat with an extra curly bracket and two semi-colons :)

      ---
      my name's not Keith, and I'm not reasonable.
[reply]
[d/l]
        sysread $sock, $total_bytes_to_read, 20;  # could get less here too...

        [download]
[reply]
[d/l]

Back to Seekers of Perl Wisdom