note
haukex
<p>There are quite a few techniques you can use to make your regexen nicer, any combination of which might be useful to you, see for example <c>/x</c>, <c>/e</c>, <c>/r</c>, <c>\K</c>, and lookarounds in [doc://perlre#Modifiers|perlre]. In the following example I've thrown all of them together into one, which may be overkill. <small><i>(I see [ikegami] has posted something similar, albeit non-functional, while I was composing this.)</i></small></p>
<!--
s{
( ^ \#[ ]START \n )
( .*? )
( ^ \#[ ]END \n )
}{
$1 . ( $2 =~ s/^[ $]*//rg ) . $3
}xsmeg;
-->
<c>
my $data = <<'END';
foo123bar
# foo123bar foo456bar
# xyz foo789bar abc
foo456bar
END
$data =~ s{
^ # beginning of line
\h* \# \h* # comment lines
\K # keep everything up to here in replacement
(?<comment> \N*) # capture the comment
$ # end of line
} { handle_foobar( $+{comment} ) }msxge;
sub handle_foobar {
return shift =~ s{
foo \K (\d+) (?= bar )
}{
$1 =~ tr/0-9/a-j/r
}msxger;
}
</c>
<blockquote><i>I could turn the string into a line-list</i></blockquote>
<p>Note it's also possible to [doc://open] a string as an in-memory filehandle:</p>
<c>
my $str = <<'END';
Hello
# START
World
# END
Aaa
# START
Bbb
# END
Ccc
END
open my $fh, '<', \$str or die $!;
while (<$fh>) {
chomp;
if ( /^# START/ .. /^# END/ ) {
print "<$_>\n";
}
}
close $fh;
</c>
<p>Also, a more advanced regex technique is <c>m/\G.../gc</c> parsing, which is described in [doc://perlop#\G-assertion|perlop]. Also, as for your example [id://11138614|here], if the delimiters need to be escaped, see [mod://Regexp::Common::delimited].</p>
11138609
11138609