monkdiscuss
Limbic~Region
All,
<br />
I have found some of the most interesting links, both internal and external, from visiting homenodes. The problem is that by visiting random homenodes, you are extremely likely to end up on one with little to no content.
<p>
I asked around in the CB as well as [Super Search]ed, but didn't find anything that did exactly what I wanted. The closest was [id://106489] by [blakem], which contrary to the title would allow you to surf to random homenodes with a minimun XP. The trouble is it is b0rk ATM (at least for me). Even if it were working, having XP makes no guarantee a monk has put something on their homenode. In the CB, [atcroft] mentioned parsing the PM Stats.
</p>
<p>
Here was my criteria for including a homenode:
<ul>
<li> Homenode length > 500 and XP > 200 </li>
XP is a measure of participation. That participation comes in many formes (logging in every day, voting, posting, etc), which tells me I am more likely to find the content I am looking for.
<li> Homenode length > 500 and account created > 1 yr and last here < 45 days</li>
While participation (XP) is a good indicator of quality content, not all monks are as obsessed with [Monastery Gates|The Monastery] as I am. Some monks have been around for a while, chosen to take the [149675|17]<sup>th</sup> seriously, but only visit occasionally.
</ul>
</p>
<p>
Here is the code
</p>
<readmore>
<CODE>
#!/usr/bin/perl
use strict;
use warnings;
use HTML::TableContentParser;
use Time::Local;
use WWW::Mechanize;
use constant ID => 1;
use constant CREATE => 3;
use constant STATS => 4;
use constant LAST => 4;
use constant EXP => 5;
use constant LENGTH => 11;
# length && ( rep || create && last )
my %opt = (
length => 500,
exp => 200,
create => 365,
last => 45,
url => 'http://tinymicros.com/pm/index.php?goto=monkstats&sortopt=15&sortlist=15,1,3&',
pos => 0,
);
my $finished;
my $mech = WWW::Mechanize->new( autocheck => 1 );
my @homenodes;
while ( ! $finished ) {
$mech->get( $opt{url} . '&start=' . $opt{pos} );
my $table = HTML::TableContentParser->new()->parse( $mech->content() );
for my $row ( @{ $table->[ STATS ]{rows} } ) {
my $length = Get_Length( $row );
next if ! defined $length;
if ( $length < $opt{length} ) {
$finished = 1;
last;
}
my $id = Get_ID( $row );
push @homenodes , $id if defined $id;
}
$opt{pos} += 50;
}
sub Get_Length {
my $row = shift;
my $data = ${ $row->{cells} }[ LENGTH ]{data};
($data) = $data =~ /(\d+)/ if defined $data;
return $data;
}
sub Get_ID {
my $row = shift;
my ($id) = ${ $row->{cells} }[ ID ]{data} =~ /(\d+)/;
my ($exp) = ${ $row->{cells} }[ EXP ]{data} =~ /(\d+)/;
return $id if $exp >= $opt{exp};
my $create = Get_Days( ${ $row->{cells} }[ CREATE ]{data} );
my $last = Get_Days( ${ $row->{cells} }[ LAST ]{data} );
return $create >= $opt{create} && $last <= $opt{last} ? $id : undef;
}
sub Get_Days {
my $then = shift;
($then) = $then =~ m|<NOBR>(.*)</NOBR>|;
my ($yr, $mon, $day, $hr, $min, $sec) = split /[ :-]/ , $then;
my $stamp = timelocal ($sec, $min, $hr, $day, --$mon, $yr);
return int ( (time - $stamp) / 86_400 );
}
print "<ul>\n";
print "<li>[id://$_]</li>\n" for @homenodes;
print "</ul>\n";
</CODE>
</readmore>
<p>
As of this posting, there were 871 homenodes that fit this criteria. The list <i>may</i> be on my [pad://Limbic~Region|scratch pad] depending on how long it takes me to get through them all.
</p>
<div class="pmsig"><div class="pmsig-180961">
<p>
Cheers - [Limbic~Region|L~R]
</p>
</div></div>