use XML::LibXML;

my $string = q|
<Root>
  <Parent>
    <child1>Child 1</child1>
    <child2>Child 2</child2>
    <child3>Child 3</child3>
  </Parent>
</Root>|;

my $doc = XML::LibXML->load_xml(string => $string);
my @nodes = $doc->findnodes('//Parent');
for my $node (@nodes) {
    my @childnodes = $node->childNodes or next;
    for my $cnode (@childnodes) {
        if ($cnode->nodeName =~ m/^child/) {
            print 'name: '. $cnode->nodeName . ', ';
            print 'content: '. $cnode->textContent ."\n";
        }
    }
}

# Output:
# name: child1, content: Child 1
# name: child2, content: Child 2
# name: child3, content: Child 3
[download]

Thanks this helps.
one more question is there any way to ignore empty lines when copying nodes? Any expression I can use to delete all empty lines ?

Based on your description I'm not 100% sure which of the following two things you want to achieve, so let me address both:

A) Get a list of all child nodes of the Parent node

One solution is to match the Parent node via an XPath expression, and then call the childNodes method on it (which is what tangent already suggested above).

An alternative solution is to use an asterisk wildcard directly in the XPath expression, e.g. in your example the expression passed to findnodes would become '//Parent/*'.
However if there are multiple Parent nodes in the document, this would return all their children as one flat list, whereas tangent's solution allows you to handle each set separately.
Another difference is that the asterisk expression only matches element nodes, whereas the childNodes method also lists text or CDATA nodes (including whitespace strings in between the child elements, although there is an alternative method called nonBlankChildNodes which avoids that).

If you are indeed only interested in the child elements, but want to process each set separately in case of multiple Parent nodes, you could either combine childNodes with a check for nodeName (like tangent's solution does), or use a stand-alone asterisk-query:

my $doc = XML::LibXML->load_xml( ... );

foreach my $parent ($doc->findnodes('//Parent')) {
    my @childElements = $parent->findnodes('*');
    
    # ...do stuff with @childElements...
}
[download]

B) Get a string serialization of the Parent node, but with the actual Parent start/end tags stripped...

...akin to the .innerHTML property available in JavaScript/DOM.

XML::LibXML does not provide this feature, and the reason is probably that, unlike with HTML, an XML snippet requires a single root element in order to be valid XML.

You could still achieve it by getting the list of child nodes (see section A above), calling the toString method on each, and concatenating the resulting strings:

my $doc = XML::LibXML->load_xml( ... );

foreach my $parent ($doc->findnodes('//Parent')) {
    print "Found Parent node with the following XML content:";
    print innerXML($parent);
}

sub innerXML { join '', map { $_->toString } shift->childNodes(); }
[download]

Or by calling toString directly on the Parent node, and using regexes to try and strip off the outer start/end tags (but this will be messy and error-prone).

You could always use the start-with function:

my @nodes = $root->findnodes( '/Root/*/*[starts-with(name(), "child")]
+' );
[download]

I think you're taking the OP's example XML snippet too literally... :)

use warnings;
use strict;
use XML::Twig;

my $xml=<<'XML';
<Root>
  <Parent>
    <child1>Child 1</child1>
    <child2>Child 2</child2>


    <child3>Child 3</child3>
    
    <ufo> Ufo there!</ufo>
  </Parent>
</Root>
XML


my $twig= new XML::Twig(
                          pretty_print => 'indented',
                          twig_handlers => { '/Root/Parent/*' => \&fie
+ld },
);

$twig->parse( $xml);

sub field
  { my( $twig, $field)= @_;
    return unless $field->gi() =~ /^child/i;
    $field->print;  #OR print $field->text();
 }

#OUTPUT
#
#    <child1>Child 1</child1>
#    <child2>Child 2</child2>
#    <child3>Child 3</child3>
[download]

I humbly think that xpath are not intended to do match as in your case (child1, child2, child3..)

Hmm, but they seem to do exactly that, which kinda means they are intended to do it

$ xmllint --xpath " //Parent " foot.xml
<Parent>
    <child1/>
    <child2/>
    <child3/>
  </Parent>
  
$ xmllint --xpath " //Parent/* " foot.xml
<child1/><child2/><child3/>

$ xmllint --xpath "  /Root/*/*[starts-with(name(), 'child')]  " foot.x
+ml
<child1/><child2/><child3/>
[download]

... design for your data ...

I think too often the person asking how-something-xml doesn't have a choice in the design :)

i suspected to be wrong there. thanks. Maybe that syntax (strats-with(name)..) is not available in XML::Twig, or, more probably i'm not able to get rid of:


  my @all = $twig->get_xpath ('/Root/Parent/child*');
  #gives:error in xpath expression...

  my @all = $twig->get_xpath ('/Root/*/*[starts-with(name(), "child")]
+');
  #also gives error in xpath expression..

  #someresults with the findnodes method..
[download]

XML::Twig docs says these methods are similar to the XML::LibXML method. Being probably 'similar' the key word.

Albeit, if someone is able...welcome!

L*

There are no rules, there are no thumbs..
Reinvent the wheel, then learn The Wheel; may be one day you reinvent one of THE WHEELS.