I think you may have some flawed logic in your "searchfile" subroutine. You have:

      foreach my $k ( keys %master ) {
         while ( my $line=<$foundfile> ) {
[download]

At the end of the first iteration through the foreach loop, you will have checked every line in the file. But every iteration of the foreach loop after that won't execute the while loop.

One option to is to open the file inside the foreach loop and then work through the while loop and then close the file in each iteration like this:

sub searchfile {
    my $file=shift;
    # print "open $file\n";

      foreach my $k ( keys %master ) {
         open my $foundfile, '<', $file or die "can't open $file";
         my $first=<$foundfile>;
         while ( my $line=<$foundfile> ) {
             if ($line =~ m/$k/ ) {
                 $master{$k}++ ;
                # print "$k found in $file\n";
             }
         }
         close $foundfile;         
      }
}
[download]

That's basically doing this. For every key in the hash, do the following: open the file, skip the first line, search the rest of the lines for the key (and do action if found) and close the file

Another option is to swap your foreach and while loops like this:

sub searchfile {
    my $file=shift;
    # print "open $file\n";
    
     open my $foundfile, '<', $file or die "can't open $file";
    
    my $first=<$foundfile>;
     
      while ( my $line=<$foundfile> ) {
          foreach my $k ( keys %master ){
             if ($line =~ m/$k/ ) {
                 $master{$k}++ ;
                # print "$k found in $file\n";
             }
         }
      }

    close $foundfile;         
}
[download]

This is basically doing the following: open the file, skip the first line, then for each line check to see if the matches any of the keys in the hash (and if it does, do some action) and then closes the file.

Not knowing more information about your files and their contents, I think I would personally opt to go the second route, which only opens each file once.