Hi,

search herein for XML::Simple and you will get a feeling that it is not recommended for new projects anymore. You will also find many hints to recommended modules on CPAN. (e.g. XML::Twig).

Regards
McA

XML::Simple's name is misleading, it sounds like "a simple module for complete XML handling", but it's not - it's more like "simplistic XML handling for simple XML". I find it's great for reading simple XML config files that have been designed to work with XML::Simple, but it is not an all-purpose solution, and in your case is very likely not appropriate because, among several other things, it very often doesn't maintain an XML document's structure when reading a file and writing it back.

Anyway, I'm inclined to agree with the other monks' suggestions for XML::Twig, which is great when you want to process a file piece by piece. For the case you describe, if the file isn't so big that loading it into memory is too expensive, then XML::LibXML is fine too. For example, the following deletes the <bar> element if its child <quz>'s text content is "baz".

Thank you, this is really helpful. I have two questions about the code. First of all:  $el->textContent eq 'baz' Is there a way to say find the content that ISN'T baz? Is there a neq, basically? Secondly, is there any quick way through LibXML to print back into an XML file, or do I just need to use normal perl file output for that?

Is there a neq, basically?

Yes, ne. Refer to Equality Operators

Secondly, is there any quick way through LibXML to print back into an XML file, or do I just need to use normal perl file output for that?

XML::LibXML::Document has the methods toFile and toFH, or you can use toString and print it to a file yourself.

instead of XML::Simple use XML::Rules, see more about xml rules

HTML::TreeBuilder::XPath or XML::LibXML with tools like xpather.pl/htmltreexpather.pl which can give you paths to start with, and all the links here Re: Retrieve select information from HTML, they're examples(for tree-xpath and others)/walkthroughs/tutorials ...

Perhaps you can help me with Twig, then. What I want to do is search within a parent node for a specific text content of an element. If it doesnt match the string, then delete the entire parent node. Here's an example:

<book>
 <book1>Book1</book1>
  <title>Title of Book 1</title>
   <genre>Fantasy</genre>
</book>
[download]

What I'd like to do in this case is search within each <book> and see if the title matches "Title of Book 1". If it doesn't, I want that entire <book> deleted. Does this make sense?

See the section "Building an XML filter" of XML::Twig. Here's a quick implementation:

use XML::Twig;
open my $ofh, '>', $output_filename or die $!;
XML::Twig->new(
  twig_print_outside_roots => $ofh,
  keep_spaces => 1,
  twig_roots => {
    book => sub {
      my ($twig, $book) = @_;
      if ($book->first_child_text('title') eq 'Title of Book 1') {
        $book->flush($ofh);
      }
      else {
        $book->purge;
      }
      return 1;
    }
  },
)->parsefile($input_filename);
close $ofh;
[download]

I would say that your example is probably over simplistic, so I've expanded on and cleaned it up slightly:

<library>
 <book>
  <book1>Book1</book1>
  <title>Title of Book 1</title>
  <genre>Fantasy</genre>
 </book>
 <book>
  <book2>Book2</book2>
  <title>Not the Title of Book 1</title>
  <genre>Fantasy</genre>
 </book>
</library>
[download]


Now that we have something that's a little bit easier to show off some stuff, here's an example that does exactly what you ask.

use strict;
use warnings;
use XML::Twig;
use Data::Dumper;
my $DATA = '
<library>
 <book>
  <book1>Book1</book1>
  <title>Title of Book 1</title>
  <genre>Fantasy</genre>
 </book>
 <book>
  <book2>Book2</book2>
  <title>Not the Title of Book 1</title>
  <genre>Fantasy</genre>
 </book>
</library>
';

my $source_twig = XML::Twig->new('pretty_print' => 'indented');
$source_twig->safe_parse($DATA);

foreach my $book ($source_twig->root->children('book')) {
  if ($book->first_child('title')->text() ne 'Title of Book 1') {
    $book->cut()
  }
}
$source_twig->print();
[download]


And it's output:

<library>
  <book>
    <book1>Book1</book1>
    <title>Title of Book 1</title>
    <genre>Fantasy</genre>
  </book>
</library>
[download]