http://qs1969.pair.com?node_id=11112820


in reply to Mojo database routing

How to get form parameters and placeholders is covered in Mojolicious::Guides::Tutorial. I see you've commented out Mojo::SQLite, but I personally like these Mojo-style DB adapters.

Form parameters don't normally get put in the URL in the way you seem to be hoping. One possible solution would be JavaScript, but here is a solution without it: the HTML form gets submitted to a handler at /search, which then just redirects to the corresponding URL. Note I'm generating the form via Mojolicious::Plugin::TagHelpers.

#!/usr/bin/env perl
use Mojolicious::Lite;
use Mojo::SQLite;

helper sqlite =>
    sub { state $sql = Mojo::SQLite->new('sqlite:mydb.db') };

# disable template cache when running under morbo
app->renderer->cache->max_keys(0) if app->mode eq 'development';

app->sqlite->migrations->from_string(<<'END_MIGR')->migrate;
-- 1 up
CREATE TABLE contacts (
    id INTEGER PRIMARY KEY AUTOINCREMENT,
    name TEXT,
    department TEXT
);
INSERT INTO contacts (name,department) VALUES ('John Doe','Perl');
-- 1 down
DROP TABLE IF EXISTS contacts;
END_MIGR

get '/' => sub {
    my $c = shift;
    $c->render('main');
} => 'index';

post '/search' => sub {
    my $c = shift;
    $c->redirect_to(
        $c->url_for('name_query', query => $c->param('name') ) );
} => 'search';

get '/name/:query' => sub {
    my $c = shift;
    $c->stash( rows =>
        $c->sqlite->db->select(
            'contacts',
            ['id','name','department'],
            { name => $c->stash('query') }
        )->arrays );
    $c->render('main');
} => 'name_query';

app->start;

__DATA__

@@ main.html.ep
<!DOCTYPE html>
<html>
<head><title>Hello Mojo!</title></head>
<body>

<div>
%= form_for search => ( method => 'post' ) => begin
%= label_for name => 'Name'
%= text_field 'name', required=>'required';
%= submit_button 'Query'
%= end
</div>

% if ( my $rows = stash 'rows' ) {
    % if (@$rows) {
        <div><table border="1">
        <tr>
            <th>id</th>
            <th>name</th>
            <th>department</th>
        </tr>
        % foreach my $row (@$rows) {
            <tr>
            % foreach my $text (@$row) {
                <td><%= $text %></td>
            % }
            </tr>
        % }
        </table></div>
    % } else {
        <div><b>No records found!</b></div>
    % }
% }

</body>
</html>

[download]

Replies are listed 'Best First'.
Re^2: Mojo database routing
by rajaman (Sexton) on Feb 22, 2020 at 00:19 UTC
    Thanks @haukex, that's very helpful. Seems Mojo is pretty different from CGI in passing form parameters with GET. I have one other question:

    name => $c->stash('query')

    The above code matches exact full name (e.g. 'John Doe'). How to make make it do partial matching (and possibly case insensitive), such as:

    ..LIKE 'john%'

    ..LIKE 'john AND doe'

    ..LIKE '"john Doe"'

    ..MATCH 'NEAR("john" "doe", 0)'

    Cheers!
[reply]
[d/l]
[select]
      Seems Mojo is pretty different from CGI in passing form parameters with GET.

      Not really, CGI.pm also has an OO interface with a ->param method. Everything else is different, though :-)

      How to make make it do partial matching (and possibly case insensitive)

      That's more of an SQL question; it will depend on the database you're using. The most important thing is that if you build SQL queries yourself, you need to be very careful to quote everything correctly, usually using either placeholders or DBI's ->quote method, which in my code above you can access via $c->sqlite->db->dbh->quote(...) (or app->sqlite->...).

      SQLite and DBD::SQLite supports an extension called FTS5 that might be helpful to you. For example, if in my code you replace the CREATE TABLE with this:

      CREATE VIRTUAL TABLE contacts USING fts5(name, department);
INSERT INTO contacts (name,department) VALUES ('John Doe','Perl');
INSERT INTO contacts (name,department) VALUES ('Larry Wall','Perl');
INSERT INTO contacts (name,department) VALUES ('Gloria Wall','Perl');

      [download]

      And the $c->stash( rows => ... value with this:

      $c->sqlite->db->query(
  q{ SELECT rowid,name,department FROM contacts WHERE name MATCH ? },
  $c->stash('query') )->arrays );

      [download]

      Then you get the full power of the FTS5 extension, e.g. your query can be john OR larry, g*, etc. and it'll just work.

      Edit: Typo fix.

[reply]
[d/l]
[select]

In Section Seekers of Perl Wisdom