note
haukex
<p>I've been doing a lot of work with [mod://Mojolicious] lately and I've been liking it. It provides [mod://Mojo::IOLoop::Subprocess] to fork off a subprocess so that one doesn't block the server.</p>
<c>
#!/usr/bin/env perl
use Mojolicious::Lite -signatures;
use Mojo::IOLoop;
get '/' => sub ($c) {
$c->render(template => 'index');
} => 'index';
post '/doit' => sub ($c) {
$c->render_later;
Mojo::IOLoop->subprocess->run_p(sub {
# this code is actually running in a subprocess!
sleep 10;
return "I did the thing!";
})->then(sub (@results) {
$c->render(text => "@results");
})->catch(sub ($err) {
$c->reply->exception($err);
});
} => 'doit';
app->start;
__DATA__
@@ index.html.ep
% layout 'main', title => 'Hello, World!';
<div>
%= form_for doit => ( method=>'post' ) => begin
%= submit_button 'Do the thing'
%= end
</div>
@@ layouts/main.html.ep
<!DOCTYPE html>
<html>
<head><title><%= title %></title></head>
<body>
%= content
</body>
</html>
</c>
<p>You could combine this with e.g. aychnronous AJAX form submission like I showed [id://11114417|here], or one could probably even send progress messages (a feature provided by [mod://Mojo::IOLoop::Subprocess]) to the browser using something like Javascript's EventSource API, which I included an example of [id://11114488|here].</p>
<p><b>Update 2022-04-07:</b> I've now posted an example of just that [id://11142798|here].</p>
11117744
11117744