Re^3: Pass hard coded param CGI post

I am on a shared server which does not allow too much. It comes with CGI enabled and I think installing and using the Mojolicious framework is not possible.

Yes, even you can use CPAN - Mojolicious is pure-Perl, with no non-core dependencies, which makes it especially suitable for installing in situations like these.

I had a look at the framework, and it seems to me that it would need quite an investment in time to set it up and learn it.

Well, for really simple CGI applications, sure, you could use e.g. CGI::Simple. But I've been using Mojolicious more and more recently, and I think it's good even for really simple stuff, and IMHO learning it is definitely worth the investment because you'll get so much more functionality out of a seemingly simple app. To get started, have a look at Mojolicious::Guides::Tutorial. I also have several examples on my scratchpad.

However, I could not find any way to perform in Mojo the same basic things I am doing in CGI, so to say, out of the box.

This is the equivalent to the code you showed:

#!/usr/bin/perl
use Mojolicious::Lite -signatures;

get '/' => sub ($c) {
    $c->render(template => 'index');
} => 'index';

get '/delete' => sub ($c) {
    my $token = $c->param('token');
    my $key = $c->param('key');
    my $usr = $c->param('usr');
    $c->render( text=>"Token: $token - Key: $key - Usr: $usr" );
} => 'delete';

app->start;

__DATA__

@@ layouts/main.html.ep
<!DOCTYPE html>
<html>
<head><title><%= title %></title></head>
<body>
%= content
</body>
</html>

@@ index.html.ep
% layout 'main', title => 'Hello, World!';
<div>
%= form_for delete => ( method=>'get' ) => begin
%= hidden_field key => 'gfgf'
%= hidden_field usr => 'rob'
<div class="form-group">
    %= label_for id => 'Your token'
    %= text_field token=>'Default', class=>"form-control", id=>"id", r
+eadonly=>undef
</div>
<div class="form-group">
    %= submit_button 'Delete', class=>"btn btn-primary"
</div>
%= end
</div>
[download]

Though you should probably change get '/delete' to post '/delete' and method=>'get' to method=>'post'. This script will work both when started via e.g. morbo script.pl, and as a CGI script automatically.

Comment on Re^3: Pass hard coded param CGI post Select or Download Code


Problems? Is your data what you think it is?
	PerlMonks