> I need a very simple GUI ..

The simplest gui toolkit here around is Tk and something like Re^3: perl/tk show script progress can be what you are for.

See also my bibliotheca which has a link to another interesting gui framework (not yet used by me): Prima

PS how to display output of a process in text widget in real time is interesting and related too: pay attention to Marshall's and zentara's examples. As side note all zentara's Tk examples here at perlmonks are worth to read being our Tk guru, among others ;)

PPS another one: Perl::TK - fileevent and script execution theory

L*

Thank you very much for this, this is a whole lot of precious resources!

Tk::DoCommand is exactly what I needed, unfortunately I had encountered some problems during my tests, because I need to print out some escape sequences, details: Re^2: GUI to dynamically show program output

.

G'day markong,

"I'm open to suggestion on alternative GUIs"

That's lucky, because I don't know Gtk2. :-)

Here's a Tk solution which, I believe, does the sort of thing you want.

#!/usr/bin/env perl

use strict;
use warnings;

use Tk;
use Tk::ROText;

my $mw = MainWindow::->new();
$mw->geometry('512x288+100+150');

my $ctrl_F = $mw->Frame(
)->pack(-side => 'left', -fill => 'y');
my $text_F = $mw->Frame(
)->pack(-side => 'left', -fill => 'both', -expand => 1);

my $fill_x = $ctrl_F->Button(-text => 'Fill X')->pack();
my $fill_y = $ctrl_F->Button(-text => 'Fill Y')->pack();
my $text = $text_F->Scrolled('ROText',
    -scrollbars => 'osoe', -wrap => 'none',
)->pack(-fill => 'both', -expand => 1);

$fill_x->configure(-command => sub {
    $_->configure(-state => 'disabled') for $fill_x, $fill_y;
    my $ms = 50 * (1 + int rand 10);
    my $iters = 1 + int rand 100;
    my $iter = 0;
    my $id;
    $id = $mw->repeat($ms, sub {
        if (++$iter < $iters) {
            text_show($text, 'X');
        }
        else {
            text_show($text, "\n");
            $id->cancel;
            $_->configure(-state => 'normal') for $fill_x, $fill_y;
        }
    });
});

$fill_y->configure(-command => sub {
    $_->configure(-state => 'disabled') for $fill_x, $fill_y;
    my $ms = 50 * (1 + int rand 10);
    my $iters = 1 + int rand 100;
    my $iter = 0;
    my $id;
    $id = $mw->repeat($ms, sub {
        if (++$iter < $iters) {
            my $str = 'Y' x (1 + int rand 100) . "\n";
            text_show($text, $str);
        }
        else {
            $id->cancel;
            $_->configure(-state => 'normal') for $fill_x, $fill_y;
        }
    });
});

MainLoop;

{
    my ($line, $char); BEGIN { ($line, $char) = (1, 0) }

    sub text_show {
        my ($text, $str) = @_;

        $text->insert("$line.$char" => $str);
        $text->see("$line.$char");

        if (-1 < index $str, "\n") {
            $line += $str =~ y/\n//;
            $char = length(substr $str, rindex $str, "\n") - 1;
        }
        else {
            $char += length $str;
        }
    }
}
[download]

Notes:

• The "Fill X" button simulates the textual "progress bar" you mentioned.
• The "Fill Y" button simulates lines of output from your commands.
• The anonymous block at the end is where the output display occurs. You'll want to feed you command/progressbar output to text_show().
• I've allowed the text window to scroll horizontally as well vertically to show you that option. You may want to change -wrap => 'none' to -wrap => 'char' (which, I'd guess, is what wrap_mode => 'char' does in your Gtk2 code).
• The Tk::ROText widget does, I assume, the same as the editable => 0 does in your Gtk2 code. Take a look at Tk::Text for all the non-read-only features.
• The automatic scrolling is handled by $text->see("$line.$char");.
• You may also want to look at Tk::fileevent. That's probably what I'd use; with the call to text_show() in the callback.

kcott, thank you very much!

The example really does what I need but unfortunately it doesn't show correctly the progress bar of the command. This is probably due to the fact that the textual progress bar includes a counter which is implemented by printing "\r" char (below the entire C function).

void doProgress(char* label, size_t step, size_t total) {
    //progress width
    const int pwidth = 60;

    //minus label len
    size_t width = pwidth - strlen(label);
    size_t pos = (step * width) / total;

    size_t percent = (step * 100) / total;

    printf("\r%s%4d/%4d [", label, step, total);

    int i;

    //fill progress bar with =
    for (i = 0; i < pos; i++) {
        printf("%c", '=');
    }

    //fill progress bar with spaces
    printf("% *c", width - pos + 1, ']');
    printf("%3d%%", percent);
    fflush(stdout);
}
[download]

The net result is that I get a mess displayed when I add the text to the TextView, because TextView doesn't interpret char escape sequences. I get the same result using Tk::DoCommand.

After a little bit of searching I think that I could probably solve the thing by using pseudo-ttys in Tk or even embedding Xterm(1) inside Tk !

The two examples are all in python, so I'd just ask if the same can be done with Perl Tk (maybe playing with IPC::Run module pseudo-ttys support) ?

Comments and further suggestions are always welcome!

"... really does what I need but ... doesn't show correctly ... probably due to ... printing "\r" char ..."

Well, I obviously had to make an initial guess about how the textual progressbar was implemented; however, you'll be glad to know that can be very easily fixed. :-)

I rewrote the "Fill X" callback so that it gives a rough approximation of what your doProgress() is printing. I left in the all-important \r but didn't bother adding the percentage calculation.

$fill_x->configure(-command => sub {
    $_->configure(-state => 'disabled') for $fill_x, $fill_y;
    my $ms = 50 * (1 + int rand 10);
    my $iters = 1 + int rand 100;
    my $iter = 0;
    my $id;
    my $label = 'LABEL';
    $id = $mw->repeat($ms, sub {
        if (++$iter <= $iters) {
            text_show($text,
                sprintf "\r%s%4d/%4d [%s]",
                    $label, $iter, $iters, '=' x $iter
            );
        }
        else {
            text_show($text, "\nDone!\n");
            $id->cancel;
            $_->configure(-state => 'normal') for $fill_x, $fill_y;
        }
    });
});
[download]

I then added some code to text_show() to handle the \r.

{
    my ($line, $char); BEGIN { ($line, $char) = (1, 0) }

    sub text_show {
        my ($text, $str) = @_;

        if (0 == index $str, "\r") {
            $str = substr $str, 1;
            $text->delete("$line.0", "$line.$char");
            $char = 0;
        }

        $text->insert("$line.$char" => $str);

        if (-1 < index $str, "\n") {
            $line += $str =~ y/\n//;
            $char = length(substr $str, rindex $str, "\n") - 1;
        }
        else {
            $char += length $str;
        }

        $text->see("$line.$char");
    }
}
[download]

You may notice that I also moved the $text->see("$line.$char") statement. It logically makes more sense for this to occur after $line and $char have been recalculated; although, visually I couldn't see any difference. It probably depends on the size of the GUI window, how you've implemented scrollbars, and the value of -wrap. I'll leave you to play around with that part.

I didn't change anything else in the original code I posted. So, just change those two blocks of code; give it a whirl; and see how you go.

Minor update: With the numbers being displayed, I noticed an off-by-one error in the "Fill X" callback: I changed ++$iter < $iters to ++$iter <= $iters. The same error exists in the "Fill Y" callback: fix it if you want; it would only be noticeable if $iters randomised to 1, in which case you'd get no output.

— Ken