well since my editor has a (mostly functioning) cperl-beautify-regexp

use v5.12;
use warnings;
use Test::More;


my $str = '43:1:1; 43:1:2; 43:1:3; 43:1:4; 43:1:5; 43:1:6; 27:3:7; 27:
+3:8; 27:3:9; 65:1:4; 65:1:18';
my $exp = '43:1:1-6; 27:3:7-9; 65:1:4; 65:1:18';

my $got = $str;

$got =~ s/
             (
                 \d+:\d+:
             )                      # $1
             (
                 \d+                # (updated +)
             )                      # $2 = first $^N
             ;
             (?:                    # group w/o match
                 \s
                 \1
                 (
                     (??{ $^N+ 1 }) # include last_match + 1
                 )                  # $3 = next $^N
                 ;
             )+                     # repeat
         /$1$2-$3;/xg;


is($got, $exp, "fits");

done_testing;
[download]

Worth noting that the OP was wrong with his expectation, it's 43:1:1-6; not 43:1:1-5;

PS: still not perfect, because the input isn't terminated with a semicolon, but I'm tired now. :)

LanX,

Your code does a better job at meeting my understanding. It's still on the edge to have that $^N involved, but that is the sort of method I was hoping to learn. I'll need to use it more to get the feel of what it is doing, perhaps, but I can see that your code does do the job.

...and you found a typo in my OP. Nobody's perfect. My forearms and fingers are actually sore from typing for a solid 7-8 hours both yesterday and today, so I guess I'll lay the blame there (lame excuse, perhaps, but true nonetheless).

Blessings,

~Polyglot~

> It's still on the edge to have that $^N involved

Actually you don't really need $^N, since you can test wether $3 is even defined. It makes the code also more robust against the insertion of other match-groups.

The real power tool is the insertion of dynamically evaluated code with (??{... }) and I have to admit that I rarely need this.

use v5.12;
use warnings;
use Test::More;


my $str = '43:1:1; 43:1:2; 43:1:3; 43:1:4; 43:1:5; 43:1:6; 27:3:7; 27:
+3:8; 27:3:9; 65:1:4; 65:1:18';
my $exp = '43:1:1-6; 27:3:7-9; 65:1:4; 65:1:18';

my $got = $str;

$got =~ s(
             ( \d+:\d+: )                    # $1
             ( \d+ )                         # $2
             (?:                             # repeat
                 ;\s                         #   separator
                 \1                          #   head
                 (
                     (??{ ($3//$2) + 1 })    #   insert 1+ ($3 or $2)
                 )                           #   $3 
             )+                              # once or more
         )($1$2-$3)xg;


is( $got, $exp, "fits");

done_testing;
[download]

Cheers Rolf
_{(addicted to the Perl Programming Language :)
Wikisyntax for the Monastery}