Re^3: Errors uncaught by CGI::Carp

you can redirect your script's STDOUT to an in-memory file in a BEGIN block, then at the END, print the contents of that in-memory variable to a logfile and to the original STDOUT handle

I have tried this approach. It is working in the test environment and has been applied to one of the production scripts that I use quite a bit and from which I regularly get 500 errors. And of course, I keep testing and it isn't giving errors...but I am sure it will before long!

Here is what the top of the script looks like...

#!/usr/bin/perl -T

use CGI::Carp qw(fatalsToBrowser);

use FindBin qw($RealBin);
my $safepath;

{
    use autodie;
    
    my $fh_cgiout;
    my $memory;
    
    BEGIN {
        open $fh_cgiout, '>&', \*STDOUT;
        close STDOUT;
        open STDOUT, '>', \$memory;
    }
    
    END {
        close STDOUT;
        
        open my $fh, '>>', 'dupot.log';
        print $fh "-----\n";
        my $prefix = sprintf "DEBUG %5d %s: ", $$, scalar localtime;
        print {$fh} ($memory =~ s/^/$prefix/gmr);
        close $fh;
        
        open STDOUT, '>&', $fh_cgiout;
        print $memory;
    }
}

BEGIN {
    if ($RealBin =~ m!^(/home/xxx/yyy/(test|uk)/www)!) {
        $safepath = "$1/../lib";
    } else {
        die "Illegal use of software - visit www.way-finder.uk to use 
+this site";
    }
}
use lib "$safepath";
[download]

There's some magic in there that I don't fully understand...can I clarify?

The braces around the first BEGIN and END block are to limit the scope of use autodie; - is that right and is that 'all' they are doing?

I can see what print {$fh} ($memory =~ s/^/$prefix/gmr); is doing but could not write it from scratch! The braces are needed because the thing that is printed is being calculated on the fly instead of being a constant or intopolated from a variable - is that right?

Thanks for your help thus far...I have a rapidly growing log file capturing all the stuff output to people's browsers. Hopefully somewhere in that lot I will find the clue that unlocks my understanding of the error.

Comment on Re^3: Errors uncaught by CGI::Carp Select or Download Code

Replies are listed 'Best First'.

Re^4: Errors uncaught by CGI::Carp
by pryrt (Abbot) on Oct 15, 2021 at 18:30 UTC

The braces around the first BEGIN and END block are to limit the scope of use autodie; - is that right and is that 'all' they are doing?

Not quite all. They are also supplying scope for the two my-variables, so that they will only be accessible by that BEGIN and END block.

I can see what print {$fh} ($memory =~ s/^/$prefix/gmr); is doing but could not write it from scratch! The braces are needed because the thing that is printed is being calculated on the fly instead of being a constant or intopolated from a variable - is that right?

The braces are not needed around $fh. I just got in the habit of using the braces because more complicated filehandle expressions, like $structure{FH}, do require the braces, as described in print. Plus it helps me visually see that the print is going somewhere other than STDOUT. I don't always do that, but I try to usually do it. And the parentheses aren't required either -- but again, I used them for my own readability. AFAICT, print $fh $memory =~ s/^/$prefix/gmr; should work just as well -- though looking at it tells me I much prefer the extra syntax I used before, for personal readability.

And writing it from scratch wasn't intuitive for me, either: I am new to the non-destructive substitution, so I had to build up to it to make sure I was confident it did what I thought it would.

[reply]
[d/l]
[select]


Syntactic Confectionery Delight
	PerlMonks