G'day ibm1620,

"I know that given is still experimental (and unpopular), but I thought it was still supported by 5.36."

The release notes, perl5360delta, whose first section is "use v5.36", has:

"... with this release, the experimental switch feature, present in every feature bundle since they were introduced in v5.10, has been removed from the v5.36 bundle. ..."

See "perlsyn: Switch Statements" for more about the switch feature.

Thanks! So, in order to allow my method of processing command line options to continue to work while using the v5.36 features, I can write:

use v5.36;
use feature qw/switch/;
no warnings "experimental::smartmatch"; 
no warnings "experimental::for_list";

for my ( $opt, $val ) (%$opts ) {
    given ($opt) {
        when ('h') { HELP_MESSAGE(); }
        when ('v') { ++$verbose; }
        when ('r') { ++$recursive; }
        when ('c') { ++$confirm; }
        when ('f') { ++$force; }
        default    { die "*** BUG: no handler for -$opt.\n"; }
    }
}
[download]

To me, this reads the best. I guess that if given goes away I'll replace it with for .. reluctantly, because "for" has always implied looping to me.

what would be the modern way to write that loop?

Assuming you are actually asking about the given statement rather than the loop which contains it, the answer is in the FAQ.

Thanks. I was actually talking about the while-loop as well, since it contains the declaration of $v that seems to have been ignored.

The error about the undeclared $v comes after the 2 syntax errors. Once you see a syntax error all bets are off concerning the rest of the compilation. You need to fix the syntax errors first and only then worry about everything else.

---

🦛

In this application you can replace the given/when with a dispatch table. Other changes you can make since you use v5.36;:

• You no longer need use strict; -- this is implied by use v5.12; or above;
• You can use the experimental for-list syntax, though for the moment you will need to silence the "experimental" warning;
• You can either eliminate the no if ... or just disable the warnings for smartmatch unconditionally, depending on whether you use them elsewhere in your code.

The each() built-in is discouraged because there is only a single iterator for a given hash, which can be reset in un-obvious ways -- see the docs for each() for details.

My take on your boilerplate, with all the above incorporated, is:

#!/usr/bin/env perl

use v5.36;     # was 'use 5.010;'
#use warnings; # unnecessary now!
#use strict;   # unnecessary since 5.12.
no warnings 'experimental::for_list';
#no if $] >= 5.018, warnings =< "experimental::smartmatch";
use Getopt::Std;
my %opts;
getopts( 'hvi:', \%opts ) or die "getopts failed\n";
my $verbose;
my $infile;
for my ( $k, $v ) ( %opts ) {
    state $dispatch = {
	h => sub { ...; },
	v => sub { ++$verbose; },
	i => sub { $infile = $_[1]; },
    };
    my $code = $dispatch->{$k}
	or die "*** BUG: no handler for -$k.\n";
    $code->( $k, $v );
}

Note that the subroutines in the dispatch table do not close over your loop variables, so you must pass them in explicitly.

Interesting!

I made the following changes:

#!/usr/bin/env perl

use v5.36;
no warnings 'experimental::for_list';
use Getopt::Std;
my %opts;
getopts( 'hvi:', \%opts ) or die "getopts failed\n";
my $verbose;
my $infile;
for my ( $k, $v ) ( %opts ) {
    state $dispatch = {
        h => sub { say 'HELP!'; exit },
        v => sub { ++$verbose; },
        i => sub ($file) { $infile = $file; },
    };
    my $code = $dispatch->{$k}
        or die "*** BUG: no handler for -$k.\n";
    $code->( $v );
}
say "infile = ", $infile // 'undefined';
[download]

I couldn't see any reason to pass $k into the sub; also, made use of sub signature.

while ( my ( $k, $v ) = each %opts ) {
    for ($k) {
        if    (/h/) { ...; }
        elsif (/v/) { ++$verbose; }
        elsif (/i/) { $infile = $v; }
        else        { die "*** BUG: no handler for -$k.\n"; }
    }
}
[download]

or a 'dispatch table' for more complex switches.

while ( my ( $k, $v ) = each %opts ) {
    state %dispatch = (
        h => sub{...;},
        v => sub{ ++$verbose;},
        i => sub{ $infile = $v; },
    );

    die "*** BUG: no handler for -$k.\n" if !exists $dispatch{$k};
    &{$dispatch{$k}};
}
[download]