#!/usr/bin/perl

use strict; # https://perlmonks.org/?node_id=11147096
use warnings;

my $testdata = <<END;
sys ecm cloud-provider /Common/aws-ec2 {
    description "The aws-ec2 parameters"
    property-template {
        account { }
        availability-zone {
            valid-values { a b c d }
        }
        instance-type {
            valid-values { t2.micro t2.small t2.medium }
        }
        region {
            valid-values { us-east-1 us-west-1 }
        }
    }
}
END

local $_ = $testdata; # NOTE expr() expect input in $_
my $parse = expr();
use Data::Dump 'dd'; dd $parse;

use List::AllUtils qw( all );
sub fixhash
  {
  local $_ = shift;
  if( ref $_ eq 'ARRAY' )
    {
    all { ref $_ eq 'HASH' } @$_ and return { map { map fixhash($_), %$_ } @$_ };
    return [ map fixhash($_), @$_ ];
    }
  elsif( ref $_ eq 'HASH' )
    {
    return { map fixhash($_), %$_ };
    }
  else { return $_ };
  }

sub expr
  {
  /\G\s+/gc;
  my $e = [];
  $e =
    /\G\s+/gc ? $e :
    /\G([^{}\s]+) "(.*?)"/gc ? [ @$e, { $1 => $2 } ] :
    /\G([^{}\s]+) \{/gc ?  [ @$e, { "$1" => (expr(),
        /\G\}/gc || die pos($_), ' b missing }', substr $_, pos($_))[0] } ] :
    /\G([^{}\s]+)/gc ? [ @$e, $1 ] :
    return fixhash($e) while 1;
  }