#!/usr/bin/perl

use strict; # https://perlmonks.org/?node_id=11147096
use warnings;

my $testdata = <<END;
sys ecm cloud-provider /Common/aws-ec2 {
    description "The aws-ec2 parameters"
    property-template {
        account { }
        availability-zone {
            valid-values { a b c d }
        }
        instance-type {
            valid-values { t2.micro t2.small t2.medium }
        }
        region {
            valid-values { us-east-1 us-west-1 }
        }
    }
}
END

sub expr
  {
  /\G\s+/gc;
  my $e = [];
  $e =
    /\G\s+/gc ? $e :
    /\G([^{}\s]+) "(.*?)"/gc ? [ @$e, { $1 => $2 } ] :
    /\G([^{}\s]+) \{/gc ?  [ @$e, { "$1" => (expr(),
        /\G\}/gc || die pos($_), ' missing }', substr $_, pos($_))[0] } ] :
    /\G([^{}\s]+)/gc ? [ @$e, $1 ] :
    return $e while 1;
  }

use List::AllUtils qw( all );
sub fixhash
  {
  local $_ = shift;
  return ref $_ eq 'ARRAY'
    ? ( all { ref $_ eq 'HASH' } @$_ )
      ? { map fixhash($_), map %$_, @$_ }
      : [ map fixhash($_), @$_ ]
    : ref $_ eq 'HASH'
      ? { map fixhash($_), %$_ }
      : $_;
  }

local $_ = $testdata; # NOTE expr() expects input in $_
my $parse = fixhash expr();
pos($_) < length $_ and die "incomplete parse ", substr $_, pos($_);
use Data::Dump 'dd'; dd $parse;