This seems to be a simple syntax error. The DSN string is too long:

qq(dbi:SQLite:dbname=$db,'','',{ ...
[download]

The qq() extends beyond the first comma, which is not what you want. You want:

qq(dbi:SQLite:dbname=$db),'','',{ ...
[download]

Usually, in such situations, I try to separate the steps:

my $dsn = "qq(dbi:SQLite:dbname=$db)";
my $user;
my $password;
my %dbi_options = (
    RaiseError => 1,
    PrintError => 1,
    sqlite_open_flags => SQLITE_OPEN_READONLY,
);

my $dbh = DBI->connect($dsn, $user, $password, \%dbi_options);
[download]

Ah ah ah Corion what a shame from my part :)

I modified the code but it fails anyway with empty var (both cookiesTEST.sqlite and cookies.sqlite tested) so it access the DB but still fails reading it

use strict;
use warnings;
use Data::Dumper;
use DBI;
use DBD::SQLite;
my $db = $ENV{AppData}.'\Mozilla\Firefox\Profiles\nwk2oixj.default-rel
+ease\cookiesTEST.sqlite';
die "DB file not found!" unless -e $db;

print "sqlite DBD version: $DBD::SQLite::sqlite_version\n";

my $dsn = qq(dbi:SQLite:dbname=$db);
my $user;
my $password;
my %dbi_options = (
    RaiseError => 1,
    PrintError => 1,
    sqlite_open_flags => 'SQLITE_OPEN_READONLY',
);

my $dbh = DBI->connect($dsn, $user, $password, \%dbi_options);
my $sth = $dbh->prepare(q(SELECT * FROM moz_cookies )); 
$sth->execute(); # PS added this and it works :)

print Dumper $sth->fetchall_arrayref({});

__END__

sqlite DBD version: 3.39.4
$VAR1 = [];
[download]

L*

PS ..obviously executing the statement helps :) thanks 1nickt++

There are no rules, there are no thumbs..
Reinvent the wheel, then learn The Wheel; may be one day you reinvent one of THE WHEELS.

The open manpage of SQLite also shows the ?immutable parameter when using the uri= form of connecting to a DB. With that, I am able to read the Firefox cookies from a live SQLite database while Firefox is running.

use strict;
use warnings;
use Data::Dumper;
use DBI;
use DBD::SQLite;

my $mozilla_path = "$ENV{AppData}\\Mozilla\\Firefox\\Profiles";
opendir my $dh, $mozilla_path
    or die "Couldn't read Mozilla profiles directory $mozilla_path: $!
+";
my ($profile) = grep { /\.default/ } readdir $dh;

my $file = "$mozilla_path/$profile/cookies.sqlite";
$file =~ s!\\!/!g;
die "DB file '$file' not found!" unless -e $file;

print "sqlite DBD version: $DBD::SQLite::sqlite_version\n";

my $dsn = "dbi:SQLite:uri=file:///$file?immutable=1";
my $user;
my $password;
my %dbi_options = (
    RaiseError => 1,
    PrintError => 1,
    sqlite_open_flags => 'SQLITE_OPEN_READONLY',
);

my $dbh = DBI->connect($dsn, $user, $password, \%dbi_options);
my $sth = $dbh->prepare(q(SELECT * FROM moz_cookies )); 
$sth->execute;
print Dumper $sth->fetchall_arrayref({});
[download]

The URI needs to be different between Windows and Unixish path specifications, but the SQLite documentation has examples for all of them.

Hello Corion,

just to mention all combinations, I can read the live cookies.sqlite DB even commenting out the sqlite_open_flags => 'SQLITE_OPEN_READONLY'

L*

There are no rules, there are no thumbs..
Reinvent the wheel, then learn The Wheel; may be one day you reinvent one of THE WHEELS.

Hi Discipulus,

Don't forget $sth->execute; ...

Hope this helps!