Also, you cannot export lexical variables (declared with my). You can export package global variables (declared with our), but it's not recommended. It seems the thread mentions it.

Link updated.
What is the best way to import values from a shared file?

No, you should use [id://NUMBER] to link to other nodes. See What shortcuts can I use for linking to other information?.

The preferred thing to export from a module is a subroutine. Or, alternatively, you can switch to the object oriented approach.

Shared.pm:

package Shared;
use warnings;
use strict;

use Exporter qw{ import };
our @EXPORT_OK = qw{ test_val test_list };


sub test_val { "hello world\n" }

sub test_list {
    ( [ 'Shadow',  'Blinky' ],
      [ 'Speedy',  'Pinky'  ],
      [ 'Bashful', 'Inky'   ],
      [ 'Pokey',   'Clyde'  ],
    )
}

__PACKAGE__
[download]

test.pl:

#!/usr/bin/perl
use warnings;
use strict;

use Shared qw{ test_val test_list };

print test_val();

for my $pair (test_list()) {
    print "@$pair\n";
}
[download]

Object oriented

Shared_OO.pm:

package Shared_OO;
use warnings;
use strict;

sub new {
    my $class = shift;
    bless { test_val  => "hello world\n",
            test_list => [ [ 'Shadow',  'Blinky' ],
                           [ 'Speedy',  'Pinky'  ],
                           [ 'Bashful', 'Inky'   ],
                           [ 'Pokey',   'Clyde'  ],
                         ],
          }, $class
}


sub test_val { shift()->{test_val} }

sub test_list { @{ shift()->{test_list} } }


__PACKAGE__
[download]

test_oo.pl:

#!/usr/bin/perl
use warnings;
use strict;

use Shared_OO;

my $o = 'Shared_OO'->new;

print $o->test_val;

for my $pair ($o->test_list) {
    print "@$pair\n";
}
[download]

لսႽ† ᥲᥒ⚪⟊Ⴙᘓᖇ Ꮅᘓᖇ⎱ Ⴙᥲ𝇋ƙᘓᖇ

In general, when you are working with multiple files, and importing variables between them, you will find that requiring files ends up getting a bit complicated as your project grows. This is due to everything sharing a common namespace, but with some variables declared in some files but not others.

The usual way this is resolved in Perl is to create modules, and then import from those modules.

From the error message posted. I believe the compiler is complaining that some variables where not created using the my() operator, Hence that error. Make sure all variables or those that need to be lexical are declared using the my() operator. I believe that would save you alot of stress because you have said (use strict) hence those errors. Also make sure there are no conflicts between your variable names and those imported from other modules or required file names. Thats my little thought base on the posted error message. Hope this helps. Should i be wrong please correct me.