It's the scoping of the parentheses around the my assignment that causes the problem.

The parens have nothing to do with it. A 'my' declaration has no effect until the statement after the 'my'. This is, at least in part, so you can do:

my $x = 2;
{
    my $x = 3 * $x;
    # $x == 6
}
# $x == 2
[download]

As to your question, you can get away with:

(@$_ = keys %foo) == 1 or die "Got more than one: @$_\n" for \my @v;
[download]

But I'm not sure it is worth it.

my @v=sub{@_>1 and die "Got more than one: @_\n";@_}->(keys %x)'
[download]

And if it's not a frequent use case, please use two lines.

The next maintainer will be thankful to easily read how @v is defined:

my @v= keys %h;
die "Got extra Z: @v\n" if @v >1
[download]

Otherwise if you really need it that often, why don't you simply define a helper function?

   
  DB<100> sub check { die "Got extra Z: @_\n" if @_ >1 }

  DB<101> %h=(a=>1)
 => ("a", 1)

  DB<102> check my @v= keys %h
 => ""

  DB<103> %h=(a=>1,b=>2)
 => ("a", 1, "b", 2)

  DB<104> check my @v= keys %h
Got extra Z: a b
[download]

And if you need more flexibility in testing, use some functional magic

  DB<106> sub avoid (&;@) { 
           my $code=shift;
           my $msg = $code->(@_);
           die $msg if $msg;
           }

  DB<107> avoid { "Got extra Z: @_\n" if @_ >1 } my @v = keys %h;
Got extra Z: a b

  DB<108> %h=(a=>1)
 => ("a", 1)

  DB<109> avoid { "Got extra Z: @_\n" if @_ >1 } my @v = keys %h;

  DB<110>
[download]

but again, for the sake of readability please use a line break (even if it's a one liner)

avoid { "Got extra Z: @_\n" if @_ >1 } 
    my @v = keys %h;
[download]

And for completeness , I'm sure you could also use variable :attributes for such checks.

 my @v :check = keys %h;

See Attribute::Handlers for details.

¹)

       The declared variable is not introduced (is not visible) until 
+after
       the current statement.  Thus,

           my $x = $x;

       can be used to initialize a new $x with the value of the old $x
+, and
       the expression

           my $x = 123 and $x == 123

       is false unless the old $x happened to have the value 123.
[download]

And for completeness , I'm sure you could also use variable :attributes for such checks.

It's possible, but not straightforward. Attributes alone can't do it, because they don't happen at runtime, so they don't see the assigned values:

my @v :Nonempty = keys %h;
[download]

Nonempty has no acces to the keys of %h. Fortunately, you can use attributes with tie. It's still not easy, though: the constructor (TIEARRAY) doesn't see the assigned values, either. STORE sees them, but it's not called when the right hand side list is empty! Fortunately, there's one method that gets called in any assignment: EXTEND:

#!/usr/bin/perl
use warnings;
use strict;

{   package Array::Nonempty::Attr;
    use Attribute::Handlers;

    sub Nonempty :ATTR(ARRAY) {
        tie @{ $_[2] }, 'Array::Nonempty'
    }

}


{   package Array::Nonempty;
    use Tie::Array;
    use parent -norequire => 'Tie::StdArray';
    use Carp;

    sub EXTEND {
        my ($self, $size) = @_;
        croak "Cannot be empty" if 0 == @$self && 0 == $size;
        $self->SUPER::EXTEND($size)
    }

}

use parent -norequire => 'Array::Nonempty::Attr';

my %hash_ok = ( answer => 42 );
my %hash_empty = ();

my @keys_ok :Nonempty = keys %hash_ok;

my @keys_empty :Nonempty = keys %hash_empty;
[download]

You can add other methods to check they wouldn't help you:

Read more... (532 Bytes)

To create an array that can never be empty, you'd have to implement SHIFT, POP, and SPLICE, too.

Read more... (626 Bytes)

($q=q:Sq=~/;[c](.)(.)/;chr(-||-|5+lengthSq)`"S|oS2"`map{chr |+ord
}map{substrSq`S_+|`|}3E|-|`7**2-3:)=~y+S|`+$1,++print+eval$q,q,a,
[download]

Thanks I started experimenting myself after you messaged me.

As said you'll need to tie cause Attributes happen at compile time and you have to intercept the assignment in STORE.

(didn't know about EXTEND till now)

I'm fine with using tie as long as I can untie when I'm done. Otherwise the penalty for this syntactic sugar would be to huge.

I took a simpler case, tieing a scalar, and trying to use untie $$self within STORE {}. Didn't work. (probably because dereferencing isn't allowed for untie or scope restrictions)

IMO as long we can't automatically untie, this approach shouldn't be used.

update

seems liked I didn't realy understood Tie::StdScalar yet

update

this approach with autotieref

use Attribute::Handlers autotieref => { Selfish => Tie::Selfish };

should provide the necessary reference to the tied structure, so that untieing becomes possible.

Cheers Rolf
_{(addicted to the Perl Programming Language and ☆☆☆☆ :)
Je suis Charlie!}

Seems to me the issue is the way doublequotes are interpolated. So...
      mayybe simpler still, but -- admittedly -- not one line:

#!/usr/bin/perl -w
use 5.018;
use strict;
# 1150034

my %foo = ("do"=>  "done", "eggs"  =>"green ham", "was" => "were",);

my @v;
(@v = keys %foo) == 1 or warn "Got more than one: " . @v . "\n";
print "V:@v\n";
[download]

OUTPUT:

Got more than one: 3
V:was do eggs
[download]

... the issue is the way doublequotes are interpolated.

No, per tye above, the problem is with scoping within a statement:

c:\@Work\Perl\monks>perl -wMstrict -le
"my %foo = qw(do done  eggs ham  was were);
 ;;
 my @v;
 (@v = keys %foo) == 1 or warn qq{Got more than one: @v};
 print qq{V:@v};
"
Got more than one: eggs was do at -e line 1.
V:eggs was do
[download]

---

Give a man a fish:  <%-{-{-{-<