How to ask better questions using Test::More and sample data

I encourage wisdom seekers to present sample data and use Test::More in the example code of their question. Let's look at some examples.

How do I make the regex match?

#!/usr/bin/perl

use strict;
use warnings;
use Test::More;

my $data  = "Some string here";
my $regex = qr/ fancy regex here /mxis;

like( $data, $regex, "Matching my regex" );

done_testing;
[download]

Your code fails, but readers can read this code and run it and make changes that will make it pass.

Why does my sub return an error?

#!/usr/bin/perl

use strict;
use warnings;
use Test::More;

sub mysub {
   return;
}

ok( mysub(), "Should return true" );

done_testing;
[download]

Presenting larger sample data as if you were reading a file line by line.

Use __DATA__.

#!/usr/bin/perl

use strict;
use warnings;
use Test::More;

my $wanted_matches = 2;
my $actual_matches = 0;
my $regex          = qr/ fancy regex here /mxis;

while ( my $line = <DATA> ) {
   chomp $line;

   if ( $line =~ $regex ){
      $actual_matches++;
   }
}

ok( $wanted_matches == $actual_matches, "Correct number of matches" );

done_testing;

__DATA__
line one..... 
line two..... 
....
line ten.....
[download]

Neil Watson
watson-wilson.ca

Comment on How to ask better questions using Test::More and sample data Select or Download Code

Replies are listed 'Best First'.
Re: How to ask better questions using Test::More and sample data by haukex (Archbishop) on Oct 12, 2017 at 10:31 UTC
This post makes excellent points! Just to expand a little on regex testing - having many test cases helps: #!/usr/bin/env perl use warnings; use strict; use Test::More; #use re 'debug'; # optional my $regex = qr/(foo\|bar)(quz\|baz)?$/; # "match / doesn't match" tests like "foo", $regex; like "bar", $regex; like "foobar", $regex; like "fooquz", $regex; like "foobaz", $regex; like "barbaz", $regex; like "foobarquz", $regex; like "foobarfooquz", $regex; unlike "foobarquzbaz", $regex; unlike "quzbaz", $regex; unlike "hello", $regex; unlike "foo ", $regex; # etc. # check capture groups ok "foobar" =~ $regex; is $1, "bar"; is $2, undef; ok "foobarquz" =~ $regex; is $1, "bar"; is $2, "quz"; ok "foobaz" =~ $regex; is $1, "foo"; is $2, "baz"; # etc. # and/or check return values in list context is_deeply [ "foobar" =~ $regex ], [ "bar", undef ]; is_deeply [ "fooquz" =~ $regex ], [ "foo", "quz" ]; is_deeply [ "barbaz" =~ $regex ], [ "bar", "baz" ]; # etc. # an example with /g return values is_deeply [ "foobarquzbaz" =~ /[aeiou]/g ], [ "o", "o", "a", "u", "a" ]; # same thing, written differently: my @matches = "foobarquzbaz" =~ /[aeiou]/g; is_deeply \@matches, [ "o", "o", "a", "u", "a" ]; done_testing; [download]	[reply] [d/l]
Re: How to ask better questions using Test::More and sample data by stevieb (Canon) on Feb 09, 2016 at 02:21 UTC
Updating How do I post a question effectively? definitely wouldn't be a bad thing, and these suggestions will teach good coding/testing practices as well as they do question asking.	[reply]
Re^2: How to ask better questions using Test::More and sample data by Anonymous Monk on Feb 09, 2016 at 02:39 UTC
Updating How do I post a question effectively? definitely wouldn't be a bad thing, and these suggestions will teach good coding/testing practices as well as they do question asking. It wouldn't necessarily be a good thing either :D lots of questioners can't even manage to use code tags, or do what How do I post a question effectively? or How (Not) To Ask A Question suggest Expansion isn't likely to increase its effectiveness or usefulness, more than anything more people will ignore it, if that is even possible I believe question templates are a better idea, but even they were rejected, and likely wouldn't do anything to improve questions either RFC - new shortform for newquestions with anysection dropdown/selection/option / Re: Standard way for displaying a script's output.( new question template)	[reply]


Pathologically Eclectic Rubbish Lister
	PerlMonks