use strict;
use warnings;

# usage: ./count_files.pl /var/tmp [ /path/to/dir2 ... ]
# usage: perl count_files.pl C:\

use Data::Dumper;
use File::Spec::Functions qw( catfile );

use MCE;
use MCE::Queue;
use MCE::Shared;

# Get directories to start with
my @start_dirs = @ARGV
   or die "Please specify one or more starting directories, stopped";

for ( @start_dirs ) {
   -d or die "No such directory: $_, stopped";
}

# Shared queue, counter, and arrays
my $shared_work = MCE::Queue->new( fast => 1, queue => \@start_dirs );
my $free_count  = MCE::Shared->scalar( 0 );

my $isDir       = MCE::Shared->array;
my $isFile      = MCE::Shared->array;
my $denied      = MCE::Shared->array;

# Walk routine
sub traverse {
   $free_count->decr;
   my ( $dir, $path ); my @work = $_;

   while ( defined ( $dir = shift @work ) ) {
      opendir DH, $dir or $denied->push( $dir ), next;

      $isDir->push( $dir );
      my @files;

      for ( readdir DH ) {
         next if $_ eq '.' || $_ eq '..';

         if ( -d ( $path = catfile( $dir, $_ ) ) ) {
            ( @work < 5 )
               ? push @work, $path
               : $shared_work->enqueue( $path );

            next;
         }
         elsif ( -f _ ) {
            push @files, $path;
         }
      }

      $isFile->push( @files ) if @files;
   }

   # Done with our work, let everyone know we're free
   if ( $free_count->incr == MCE->max_workers && !$shared_work->pending ) {
      $shared_work->enqueue( (undef) x MCE->max_workers );
   }
}

# Instantiate MCE and run.
MCE->new(
   max_workers => 6,

   user_begin => sub {
      $free_count->incr;
   },

   user_func => sub {
      traverse() while ( defined ( $_ = $shared_work->dequeue ) );
   },

)->run;

# Display counts.
printf "count dirs   : %d\n", $isDir->len;
printf "count files  : %d\n", $isFile->len;
printf "count denied : %d\n", $denied->len;

# print Dumper( $isDir->export  ), "\n";
# print Dumper( $isFile->export ), "\n";
# print Dumper( $denied->export ), "\n";