hilitai, with the ideas generated by the other Monks, I was able to come up with this, which worked for me on Win7 strawberry 5.24.1 and linux perl 5.8.5.

#!/usr/bin/perl

use strict;
use warnings;
my $usemod;     # if you initialize `my $usemod = 0;`, then the BEGIN 
+block's assignment to $usemod is overridden, which you don't want
our $Registry;  # this will be overridden by Win32::TieRegistry's expo
+rt of $Registry if in Windows, but

BEGIN {
    local $\ = "\n";
    if( $^O eq 'MSWin32' ) {
        eval {
            require Win32::TieRegistry;
            Win32::TieRegistry->import( Delimiter => '/' );
            $usemod = 1;
        }
    }
}

if ($usemod) {
    my $IEKey = $Registry->{'HKEY_CURRENT_USER/Software/Microsoft/Inte
+rnet Explorer/Main/'};
    print "IEKey = '$IEKey'\n";
} else {
    print "None of that stuff here\n";
}
[download]

• my 5.8.5 linux perl didn't like the use if ... (edit: or, at least, the way I tried... with some debug, it may have eventually worked), so I went with Discipulus's BEGIN block idea to make that run first

• removing the = 0 on my $usemod; allowed the $usemod variable to update in the BEGIN block
• used Perlbotics' suggestion of ->import(), though I included your Delimiter => '/' argument to the import
• made $Registry a package variable using our, which then allowed the Win32::TieRegistry->import() to clobber it with the defined version from the module, while still allowing linux perl to compile the script

edit#2: added use warnings; per best practices

edit#3: added "perl" to "linux perl 5.8.5", so it wasn't implying that was the version of linux, but rather the version of perl

Yes! Thank you all very much (and especially pryrt and haukex, who taught me something new today).

you can check $^O to see if you are running on windows: see perlvar then require the module and eventully import, if the module uses Exporter's import.

if ($^O eq 'MSWin32'){
   require Win32::TieRegistry;
   Win32::TieRegistry -> import if Win32::TieRegistry -> can ("import"
+);
}
[download]

See also use module if condition is met for suggestion about if module.

PS this kind of things are worth to reside into a BEGIN block.

L*

Hi, see if:

use if $^O =~ 'MSWin32', 'Win32::TieRegistry';
[download]

Hope this helps!

Update: added quoting to module name, see below

Works for Windows, fails on Linux:

Too few arguments to `use if' (some code returning an empty list in list context?) at /usr/lib/perl5/5.10.0/if.pm line 7.

Sorry, missed quoting the module (necessary if no args provided, like use if CONDITION, MODULE => ARGUMENTS;)

Should be:

use if $^O =~ 'MSWin32', 'Win32::TieRegistry';
[download]

... but I'm sure you saw that in the doc I linked to, right?


The way forward always starts with a minimal test.

use warnings;
use strict;

my $have_tie_registry = defined eval
    q{ use Win32::TieRegistry Delimiter=>"/"; 1 };
if ($have_tie_registry) {
    print "Have module\n";
    our $Registry;
    my $IEKey = $Registry->{'HKEY_CURRENT_USER/Software/'
        .'Microsoft/Internet Explorer/Main/'};
    print "<$_>\n" for keys %$IEKey;
}
else {
    chomp( my $err = $@//'unknown' );
    die $err if $^O eq 'MSWin32';
    print "On $^O, don't have module (reason: '$err')\n";
}
print "Continuing program...\n";

__END__

#### Linux:
On linux, don't have module (reason: 'Can't locate Win32/TieRegistry.p
+m in @INC (you may need to install the Win32::TieRegistry module) (@I
+NC contains: ...) at (eval 1) line 1.
BEGIN failed--compilation aborted at (eval 1) line 1.')
Continuing program...

### Windows:
Have module
<...>
<...>
...
Continuing program...
[download]

(Update: Note that as opposed to several of the other solutions here, this uses slightly different logic: if Win32::TieRegistry is available, it is used no matter which OS this is being run on; otherwise, if it's not available, that's only a fatal error if this is being run on Windows. Of course that logic can be changed, my point was mostly to show the my $have_module = eval q{ use Module; 1 }; technique.)

See also:

• Use 'use' in foreach
• The "right" way to make your script run with old versions of perl
• Bug in eval in pre-5.14
• Module::Load::Conditional

Uncomment this line:

   my ($Registry, $IEKey);
[download]

Output (linux):

No module
None of that stuff here
[download]

Update:

Not tested on Windows, though (not available here). If that still fails, you have another problem. Perhaps, you need to call the import() class method:

eval { require Win32::TieRegistry;
               Win32::TieRegistry->import();
};
[download]

Update2: My try on a cleanup, after getting hands on a Windows system:

use strict;
use warnings;

our $Registry;

BEGIN {
  $Win32::TieRegistry::__LOADED = eval {
    require Win32::TieRegistry;
    Win32::TieRegistry->import( Delimiter => '/' );
    1;
  };
}

sub use_mod { $Win32::TieRegistry::__LOADED; }



print "On $^O\t-> ";
if ( use_mod ) {
   my $IEKey = $Registry->{'HKEY_CURRENT_USER/Software/Microsoft/Inter
+net Explorer/Main/'};
   print 'Show status bar: ', $IEKey->{'/Show_StatusBar'}, "\n";
} else {
   print "None of that stuff here.\n";
}

__DATA__

On MSWin32     -> Show status bar: yes
On linux       -> None of that stuff here.
[download]

Yes, it works on Linux. But now it fails on Windows (the $IEKey variable should contain a value like Win32::TieRegistry=HASH(0x1dd000), but it is null).