Re: Matching multiple substrings of a string to arrays and printing those that match

@dis_dic = $f1_line;
[download]

This assigns the $f1_line to the first element of the array, and deletes anything else. You probably meant push instead.

index($f3_line, @apr_dic && @dis_dic)
[download]

index's second argument is a substring, not an array, and definitely not a boolean AND of the sizes of two arrays (@arr1 && @arr2 returns 0 if @arr1 is empty, and size of @arr2 otherwise).

Update: You might need to remove leading, trailing, or repeated commas from the last column after processing by the following code:

#!/usr/bin/perl
use warnings;
use strict;

my ($approved_filename, $discarded_filename, $data_filename) = @ARGV;

my (@approved, @discarded);

open my $in_app, '<', $approved_filename or die $!;
push @approved, $_ while <$in_app>;
chomp @approved;

open my $in_disc, '<', $discarded_filename or die $!;
push @discarded, $_ while <$in_disc>;
chomp @discarded;

my $approved_re  = '\b(?:' . (join '|', @approved)  . ')\b';
my $discarded_re = '\b(?:' . (join '|', @discarded) . ')\b';


open my $in, '<', $data_filename or die $!;
while (<$in>) {
    if (/$approved_re/) {
        s/$discarded_re//g;
        print;
    }
}
[download]

It builds two regexes, one for the approved verbs, and one for the discarded ones. Lines are printed only when the approved regex matches, and all discarded verbs are removed by the substitution.

($q=q:Sq=~/;[c](.)(.)/;chr(-||-|5+lengthSq)`"S|oS2"`map{chr |+ord
}map{substrSq`S_+|`|}3E|-|`7**2-3:)=~y+S|`+$1,++print+eval$q,q,a,
[download]

Comment on Re: Matching multiple substrings of a string to arrays and printing those that match Select or Download Code


Perl Monk, Perl Meditation
	PerlMonks