If your input is somehow fixed in it's content the easiest thing is using the flip-flop operator (see flip flop at my library and in perlop):

while (<DATA>){
    print if /SCHEDULE "DUMMY CHECK"/ .. /INTERVAL/;
}
[download]

If you just want to print 3 lines after a match (but notice you have empty lines that count! i used 6 lines..) you can use or a count, as you already have done, or use the special variable $. (explained in perlvar ) that is line number:

my $switch;
while (<DATA>){
    $switch = $. if /SCHEDULE "DUMMY CHECK"/;
    if ( $switch and $. <= $switch + 6){
        print;
    }
}
[download]

As final note @data = $_; does not make muche sense for me: you want to split the line? dont forget also to chomp

L*

Discipulus solution above is very elegant. Here's the correction of the error in your script:

use strict;
use warnings;

my $file = "input.txt";
my @data;
open (IN,"<","$file");
my $count = 0;
 while (<IN>) {
  $count = 1 if /SCHEDULE\s"(DUMMY\sCHECK)".*/;
    if ($count >= 1 and $count <= 6) {
-      @data = $_;
-      print @data;
+      $_ = <IN>;
+      print;
      $count++;  
    }
        
 }
[download]

You did not read the next line off your input file descriptor.

Crossposted to StackOverflow. Crossposting is acceptable, but it is considered polite to inform about it, so that efforts are not duplicated.

#!/usr/bin/perl
use strict;
use warnings;

while (defined (my $line = <DATA>))
{
   process_record($line) if $line =~ /^\s*SCHEDULE "DUMMY CHECK"/;
}


sub process_record
{
   my $line = shift;  #the "trigger line"
   print $line; 
   
   for (1..3)  #maybe have regex for "end of record"?
   {
      my $line = <DATA>;
      print $line;
   }
   print "\n";  #just a spacer
}

=prints
SCHEDULE "DUMMY CHECK"
DESCRIPTION "Do some stuff"
Check something
INTERVAL "10m"

SCHEDULE "DUMMY CHECK"
DESCRIPTION "Do some more stuff"
Check something
INTERVAL "30m"
=cut

__DATA__
SCHEDULE "TEST"
DESCRIPTION "Do Some stuff"
MINUTE "53"
HOUR "21"
SCHEDULE "DUMMY CHECK"
DESCRIPTION "Do some stuff"
Check something
INTERVAL "10m"
MINUTE "50"
HOUR "21"
SCHEDULE "TEST"
DESCRIPTION "Do Some stuff"
MINUTE "53"
HOUR "21"
SCHEDULE "DUMMY CHECK"
DESCRIPTION "Do some more stuff"
Check something
INTERVAL "30m"
MINUTE "50"
HOUR "21"
[download]

It's difficult to know how to best respond, or provide the best answer, without a bit more context. IOW you mention match, which is really a simple matter, as described in the linked Perl documentation -- especially if the given text file is static.

But, then again. If you need to further process that file, or perhaps another file. The (best) answer might be quite different.

tl;dr;
You will need to help us, help you.