Re: Any downsides to this slurp idiom? (updated)

Thanks everyone for your replies! :-) For completeness, here are some slurping examples, incorporating various suggestions:

The basic version (with the improved error message first suggested by haj):

my $data = do { open my $fh, '<', $file or die "$file: $!";
    local $/; <$fh> };
[download]

Opening a file with an encoding (in this case UTF-8):

my $data = do { open my $fh, '<:raw:encoding(UTF-8)', $file
    or die "$file: $!"; local $/; <$fh> };
[download]

A version that should use less memory, suggested by BrowserUk (see this discussion - Copy-On-Write, available in newer Perls, may take care of this):
```
my $data; { open my $fh, '<', $file or die "$file: $!";
    local $/; $data = <$fh> };
[download]
```
This short version, first suggested by tybalt89, however, note that as opposed to the above examples, this does not die but only emits a warning if the file could not be opened (unless FATAL warnings are in effect, the minimum needed is use warnings FATAL=>'inplace';; Update: fixed as per choroba's reply, thanks!):
```
my $data = do { local (*ARGV,$/); @ARGV=$file; <> };
[download]
```

Minor edits for clarity.

Update 2: Actually, I made a mistake in the last example when I first fixed it, it is now tested and correct.

Comment on Re: Any downsides to this slurp idiom? (updated) Select or Download Code

Replies are listed 'Best First'.
Re^2: Any downsides to this slurp idiom? by choroba (Cardinal) on Jul 09, 2018 at 16:46 UTC
Note that localizing @ARGV could be not enough (because `eof(ARGV)` might remain true). So, `my $data = do { local ( ARGV, $/ ); @ARGV = ("$file"); <> };` [download] ($q=q:Sq=~/;[c](.)(.)/;chr(-\|\|-\|5+lengthSq)`"S\|oS2"`map{chr \|+ord }map{substrSq`S_+\|`\|}3E\|-\|`7*2-3:)=~y+S\|`+$1,++print+eval$q,q,a, [download]	[reply] [d/l] [select]