Re: Re: (tye)Re: When to use Prototypes?

When you use an empty prototype (no args) for constants, the parser then knows not to interpret anything that follows as arguments for to that sub:

sub LOW_PRE_PI {3.141}
sub HI_POST_PI () {3.142}

my @n_proto = (1, LOW_PRE_PI + 5, 11, 15);
my @y_proto = (1, HI_POST_PI + 5, 11, 15);

print "@n_proto\n@y_proto";
__END__
Output:
1 3.141
1 8.142 11 15
[download]

In the first case, everything following the unprototyped version is taken as an argument list for the subroutine.

Comment on Re: Re: (tye)Re: When to use Prototypes? Download Code

Replies are listed 'Best First'.

(tye)Re4: When to use Prototypes?
by tye (Sage) on Nov 09, 2001 at 23:59 UTC

Yes, that is one difference, but I find code that makes use of that difference to be a bit of a problem. I'd probably write HI_POST_PI()+5 if I noticed.

The difference that I'm talking about is that subroutines with a () prototype that also do nothing but return a value become compile-time constants. Perl can replace instances of calls to these with the constant returned at compile time, allowing lots of interesting tricks:

> Perl -MO=Deparse -w
use strict;
sub DEBUG() { 0 }
sub SymRef() { "My::Package::hash" }
sub PI() { 3.141592 }
if(  DEBUG  ) {
    warn "Okay, we are debugging...\n";
    do_lots_of_debugging_stuff();
}
$My::Package::hash{key}= "value";
print SymRef->{key},$/;
print PI()+5,$/;
__END__
sub DEBUG () {
    0;
}
sub SymRef () {
    'My::Package::hash';
}
sub PI () {
    3.141592;
}
'???';
$My::Package::hash{'key'} = 'value';
print $My::Package::hash{'key'}, $/;
print 8.141592, $/;
- syntax OK
[download]

sub DEBUG {
    0;
}
sub SymRef {
    'My::Package::hash';
}
sub PI {
    3.141592;
}
if (DEBUG ) {
    warn "Okay, we are debugging...\n";
    do_lots_of_debugging_stuff ;
}
$My::Package::hash{'key'} = 'value';
print SymRef()->{'key'}, $/;
print PI() + 5, $/;
- syntax OK
[download]

Can't use string ("My::Package::hash") as a HASH ref
while "strict refs" in use
[download]

tye

[reply]
[d/l]
[select]


good chemistry is complicated, and a little bit messy -LW
	PerlMonks