#!/usr/bin/perl -wT
use strict;

my $bin = ascii2bin('Rolf');
my $ascii = bin2ascii($bin);

print "bin   => $bin\n";
print "ascii => $ascii\n";

sub ascii2bin {
  my $ascii = shift;
  my $bin = join '',  map {sprintf "%08b", ord($_)} split //, $ascii;
  return $bin;
}

sub bin2ascii {
  my $bin = shift;
  my $ascii = join '', map {chr(oct"0b$_")} $bin =~ /(\d{8})/g;
  return $ascii;
}

=OUTPUT
bin   => 01010010011011110110110001100110
ascii => Rolf
[download]

Or, as one-liners.....

perl -le 'print join"",map{sprintf"%08b",ord($_)}split//,pop' Rolf
perl -le 'print join"",map{chr(oct"0b$_")}pop=~/(\d{8})/g' 01010010011
+011110110110001100110
[download]

-Blake

perl -e 'print unpack"B*",shift' Rolf
perl -e 'print pack"B*",shift' 01010010011011110110110001100110

Nice. For some reason I thought this approach had been suggested and rejected by Rolf but I misunderstood which part he objected to. These are much cleaner than the ones I came up with above.

-Blake

Hi, You are so veeery close, only that I get: Can't find string terminator "'" anywhere before EOF at -e line 1.

Hi, You are getting a lot closer now. (With the last two onliners.) I get a "Can't find string terminator "'" anywhere before EOF at -e line 1." when trying them. But they do look a bit like the ones I lost. Regards Rolf

I double checked them and they work fine for me under perl 5.6.1 and unix. I did a quick test with perl 5.05_003 and they didn't work, but I didn't get the error message you're seeing. (looks like sprintf got smarter in the newer perls)

-Blake

Hi, I use perl, v5.6.1 built for MSWin32-x86-multi-thread Regards Rolf