cron: every nth week

Today, on a Linux mailing list, someone asked how to run a cron job every 4th Monday of the month. We didn't find a way to do it yet with crontab (day-of-week and day-of-month fields are ORed together..), so I wrote a perl script to check if today is the 4th Monday (or generally the nth Weekday) of the month and, if so, exit sucessfully. For example, put a cron entry to run every Monday, and then something like:

4 15 * * 1 /some/path/is_nth_weekday.pl && /your/path/yourscript
[download]

#!/usr/local/bin/perl -w
# is_nth_weekday.pl -- exit successfully if today is the
# nth weekday of the month (e.g. 4th Monday)

use strict;
use Date::Manip;

my ($today, $month, $year, $nth_weekday, $today_date,
    $nth_weekday_date, $which, $day);

$which = $ARGV[0] || '4th';
$day = $ARGV[1] || 'monday';

# get today's datetime
$today = ParseDate('today');

# get today's month and year to find $nth_weekday
($month, $year) = UnixDate($today, '%B', '%Y');
# get nth Weekday's datetime
$nth_weekday = ParseDate("$which $day in $month $year");

# get today's date
$today_date = UnixDate($today, '%Y%m%d');
# get nth Weekday's date
$nth_weekday_date = UnixDate($nth_weekday, '%Y%m%d');

# is today the nth Weekday?
if ($today_date eq $nth_weekday_date) {
        exit 0;
} else {
        exit 1;
}
[download]

Comment on cron: every nth week Select or Download Code

Replies are listed 'Best First'.

Re: cron: every nth week
by runrig (Abbot) on Jan 01, 2002 at 02:57 UTC

my $nth = shift;
die "N must be numeric" if $nth =~ /\D/;
die "Day is out of range" if $nth > 5;

my ($mday)  = (localtime)[3];
my $weeks = int(($mday-1)/7)+1;
exit 0 if $weeks == $nth;
exit 1;
[download]

[reply]
[d/l]


There's more than one way to do things
	PerlMonks