sub commify {
   my $input = shift;
   $input = reverse $input;
   $input =~ s/(\d\d\d)(?=\d)(?!\d*\.)/$1,/g;
   return reverse $input;
}
[download]

sub addcommas{
   my ($text)=@_;
   $text=reverse $text;
   $text=~s/(\d\d\d)(?=\d)(?!\d*\.)/$1,/g;
   $text=scalar reverse $text;
   return $text;
}
[download]

Very inefficient! Use:

$commas=~ s/^(-?\d+)(\d{3})/$1,$2/;
[download]

One line does it all.

hawk@rthawk.com

What happens if your value is 1_000_000 ?

"Livet är hårt" sa bonden.
"Grymt" sa grisen...

Adding just a wee tiny bit to vroom's and Fastolfe's answers...

This ditty accepts a list of numbers for commification, like so:
    my($minC, $maxC, $medC) = commify($min, $max, $med);
or so:
    my @numsC = commify(@nums);

sub commify {
  my @output;
  for(@_){
    my $input = $_;
    $input = reverse $input;
    $input =~ s<(\d\d\d)(?=\d)(?!\d*\.)><$1,>g;
    $input = reverse $input;
    push @output, $input;
  }
  return @output;
}
[download]

Originally posted as a Categorized Answer.

This regex from Benjamin Goldberg will add commas to numbers:

s/(^[-+]?\d+?(?=(?>(?:\d{3})+)(?!\d))|\G\d{3}(?=\d))/$1,/g;
[download]

It is easier to see with comments:

s/(
   ^[-+]?            # beginning of number.
   \d+?              # first digits before first comma
   (?=               # followed by, (but not included in the match) :
      (?>(?:\d{3})+) # some positive multiple of three digits.
      (?!\d)         # an *exact* multiple, not x * 3 + 1 or whatever.
   )
   |                 # or:
   \G\d{3}           # after the last group, get three digits
   (?=\d)            # but they have to have more digits after them.
)/$1,/xg;
[download]

sub commify {
   local $_  = shift;
   s{(?<!\d|\.)(\d{4,})}
    {my $n = $1;
     $n=~s/(?<=.)(?=(?:.{3})+$)/,/g;
     $n;
    }eg;
   return $_;
}
[download]

sub commify {
  local $_ = shift;
  s{(?:(?<=^)|(?<=^-))(\d{4,})}
   {my $n = $1;
    $n=~s/(?<=.)(?=(?:.{3})+$)/,/g;
    $n;
   }e;
  return $_;
}
[download]

sub commify {
  local $_ = shift;
  if (/^-?(\d{4,})/g) {
    for (my $p=$+[1]; $p>$-[1]; $p-=3) {
      substr($_,$p,0) = ','
    }
  }
  return $_;
}
[download]

I know it's eons old but I just noticed this (when looking for if there was some easy one-liner for this); it's good that that was removed from that FAQ mentioned above in the first answer.

Since return() casts in list context:

will not work (at least not as expected), as it reverses the list of the result, e.g. ('098,765,432,1') to ('098,765,432,1') (it's a list of one).

What you'd need is:

This regexp will add commas to numbers:

s/(^[-+]?\d+?(?=(?>(?:\d{3})+)(?!\d))|\G\d{3}(?=\d))/$1,/g;
[download]

Originally posted as a Categorized Answer.