This can do most of what you want. You may still have to cache the complete output for inclusion in the email.

A good quick intro is here: http://www.perl.com/pub/a/2002/09/11/log4perl.html

~J

OK, I realize Log4Perl is a lot of work rewriting your scripts, but trust me, it's worth it. For a quick start, follow the easy_init directions, and just replace all your 'print "' with $log->info(), and all the warn or 'print STDERR' calls with $log->warn().



But, of course you would like to use as much of the existing script as possible. So, to address your current problem, try using \*STDOUT directly in the IO::Tee call. I've found odd behavior when I pass it as another variable, vs passing it as \*STDOUT and \*STDERR. Call multiplex with some sort of indicator instead of the reference (a string perhaps "STDOUT" or "STDERR"), and make separate calls to IO::Tee for each of these.

To debug this, try using the handles method of IO::Tee. Add a print join(' ', $tee->handles), "\n"; (taken from the perldocs) to your multiplex method to see what it's really producing. Compare the results of using the Handle reference, vs using \*STDOUT.

I know the above works, but making separate calls to IO::Tee is pretty ugly. This is untested, but you might try creating a new filehandle object pointing to STDOUT. Perhaps something like IO::File->new(\*STDOUT), or more basic, IO::Handle->new_from_fd(fileno(STDOUT),"w"). Pass the return value from one of these to multiplex instead of the reference to the glob.

~J

IO::Multiplex

Its interesting, but I have a module that I wrote for work that does pretty close to exactly what you ask for here. The job is indeed trickier than it looks. The approach I took was to tie duped STDOUT and STDERR filehandles, and then intercept warnings and dies through a SIG handler (which can be problematic according to the docs, but not so far for me.) This works with the majority of code, but things that also play games with these filehandles can mess things up. Thankfully they seem to be rare.

Incidentally I too started with IO::Tee, and it worked (with added sig handlers), but as I started adding hooks and dealing with issues ($SIG{__DIE__} will be called even inside an eval is an example, albeit not that good a one) it soon became easier not to bother.

HTH

#!/usr/bin/perl
use strict;
use Symbol;
use IO::Select;
use IPC::Open3;

my $outlog = shift;
my $errlog = shift;
my $cmd    = shift;
my @args   = @ARGV;

open OUTLOG, ">>$outlog" or die "open $outlog: $!";
open ERRLOG, ">>$errlog" or die "open $errlog: $!";

my ( $rdr, $wtr, $err );
my $pid = open3( $wtr, $rdr, $err = Symbol::gensym, $cmd, @args );

close $wtr;

my $select = IO::Select->new( $rdr, $err );

my $outstr = '';
my $errstr = '';

while ( $select->handles ) {
    for my $handle ( $select->can_read ) {
        my $bytes = sysread $handle, my ($str), 1024;
        die "sysread: $!" unless defined $bytes;
        $select->remove($handle), next unless $bytes;
        if ( fileno($handle) == fileno($rdr) ) {
            print STDOUT $str;
            print OUTLOG $str;
            $outstr .= $str;
        }
        elsif ( fileno($handle) == fileno($err) ) {
            print STDERR $str;
            print ERRLOG $str;
            $errstr .= $str;
        }
    }
}

close $rdr;
close $err;
close OUTLOG;
close ERRLOG;

waitpid $pid, 0;

my $returncode = $? >> 8;
my $signal     = $? & 127;
my $coredump   = $? & 128;

exit unless $returncode;

my $time = localtime;

my $mail = \*STDERR;    # new Mail::Mailer;
print $mail <<END;
Process $cmd @args
returned $returncode (signal $signal, coredump $coredump)
at $time

standard output:
====
$outstr
====
standard error:
====
$errstr
====
END

close $mail;
[download]