Re: use deprecated;

That was nice food for thought.

package deprecated;

use constant EVAL_CODE => <<'END_CODE';
sub %1$s::INIT {
    my $overridden = \&%2$s;
    *%2$s = sub {
        require Carp;
        Carp::carp('%2$s() is deprecated');
        *%2$s = $overridden;
        goto &$overridden;
    };
}
END_CODE

sub import {
    my $class = shift;
    my $pkg = caller;
    eval join '', map sprintf(EVAL_CODE, $pkg, "$pkg\::$_"), @_;
}

1;
[download]

It should be obvious what is happening here, if not just change the eval to a print.

Makeshifts last the longest.

Comment on Re: use deprecated; Download Code

Replies are listed 'Best First'.
Re^2: use deprecated; by adrianh (Chancellor) on Nov 26, 2003 at 23:55 UTC
Sneaky. Like it. You'd also need to check that the subroutine actually exists at INIT time, and wrap AUTOLOAD with something appropriate if it's defined. As liz points out this won't work in mod_perl, eval and other places where the INIT phase has already occured. I guess you could use a source filter to inline the wrapping code - but that would be really evil ;-)	[reply]
Re^3: use deprecated; by Aristotle (Chancellor) on Nov 28, 2003 at 01:18 UTC
Actually, you don't even need to check whether the function exists. If you take a reference to a named but undefined function, it magically works once that function is defined. Perl is devious that way. `#!/usr/bin/perl $_ = \&x; x = sub { print "Oh my\n" }; $_->();` [download] This actually prints "Oh my". Makeshifts last the longest.*	[reply] [d/l]
Re^4: use deprecated; by adrianh (Chancellor) on Dec 03, 2003 at 01:21 UTC
Actually, you don't even need to check whether the function exists. If you take a reference to a named but undefined function, it magically works once that function is defined. Perl is devious that way. You're quite correct - I'm an idiot. In fact, I'm an idiot on two counts. My AUTOLOAD comment is equally bogus. Since everything is happening at INIT time the AUTOLOAD subroutine will already be defined. I restate my "sneaky" comment. Very nice :-)	[reply]


good chemistry is complicated, and a little bit messy -LW
	PerlMonks