First as atcroft pointed out, you most likely wanted to m// an array element, not the array (or the size of the array in fact).

Also, what if your array has less than 100 elements, in that case you would get error saying that you used unintialized value in m//. BTW, please use strict.

You probably want something like this: (your code indicated that you want to look at the first 100 elemnts only, I assume this is true)

use strict;
use warnings;

my @number = (1,2,3,9432, 5,6,7);
my $count=0;
for (0 .. (($#number < 99) ? $#number : 99)) {
    if ($number[$count]=~/^9432$/g) {
        print "match found\n"; }
    else {
        print "match failed\n";
    }
    $count++;
}
[download]

Now a little bit more on m// with array. the m// will actually be performed on scalar(@array), which is the number of elements:

use strict;
use warnings;

my @number1 = (2 .. 9432);
my @number2 = (2 .. 9433); #I intentionally avoided the use of (1.. 94
+32) here, to remove the doubt whether it compares against the last el
+ement of the array.
my @number3 = (2 .. 9434);
my $count=0;
    
if (@number1 =~ /^9432$/g) {
    print "match found\n"; 
} else {
    print "match failed\n";
}

if (@number2 =~ /^9432$/g) {
    print "match found\n"; 
} else {
    print "match failed\n";
}

if (@number3 =~ /^9432$/g) {
    print "match found\n"; 
} else {
    print "match failed\n";
}
[download]

The reason for the error message is that when you performed the @number=<CINGULAR>;, you read the entire list into an array. This means you might have something like:

$number[0] = '888-555-1212'
$number[1] = '666-555-3456'
$number[2] = '123-555-9432'
[download]

More likely what you intended in your if statement was something $number[$count] rather than @number, as this would allow you to loop thru the elements.

Hope that helps.

Try this:

open (CINGULAR, "c:/documents and Settings/david price/my documents/ci
+ngular.txt") || die "cannot open: $!";
@number=<CINGULAR>;
close (CINGULAR);
# Remove the following commented lines
# $count=0;
# while ($count<100) {
# if (@number=~/^9432$/g) {
# print "match found"; }
# else {
# print "match failed";
# }
# $count++;
# }

# and change them to:
foreach $line ( @number ) {
    if ( $line =~ /^9432$/g ) {
        print "Match found\n";
    } else {
        print "Match failed\n";
    }
}
[download]

The foreach loop allows you to loop through each element of the array, pull out one element at a time ($line), check it for the pattern, and print the appropriate message. You could add a counter in one or both sections of the conditional block to determine the number of matches/non-matches you get and print this as a summary at the end of the script. ( Beats manually counting up the "Match Found" and "Match Failed" lines in the DOS window. :) )

You're going to want to rethink your regular expression, though. :) Think about what the ^ and $ anchors are do. The way you have it written right now, you will only get a match when the number 9432 is the only text in the line.

HTH,

/Larry

Your error messages say what is wrong. The syntax @foo =~ m/$re/ does not do what you want it to.

You should look at each line separately and try the lookup with each. I'd be inclined to use the index builtin instead of regex matching, since you have the particular number you want to look for. Here's what I'd do, sticking close to what you wrote,

# after getting @number
my $wanted = '9432';
for (@number[0..99]) {
    if (index($_, $wanted) != -1) {
        print "match found\n";
    }
    else {
        print "match failed\n";
    }
}
[download]

#the foreach style sets a variable, in this case $num, to 
#each element of your array. If you did not specify a
#variable, then the special variable $_ would be set 
#each time through.

foreach my $num (@number){
   if($num =~ /9432$/){
      print "match found";
   }else{
      print "match failed";
   }
}

#a C-style for loop in which case you will be using
#the $i variable to count from 0 to the end of your array 
#based on how big it is which we now know is scalar @number.

for(my $i=0 ; $i < scalar @number ; $i++){
   if($number[$i] =~ /9432$/){
      print "match found";
   }else{
      print "match failed";
   }
}
[download]

Others pointed out the mistakes with the match. I shall talk further improvements. Here's how I would do it:

• I always use strict and use diagnostics so that Perl points out any dumb mistakes I make.
• Instead of traditional filehandles (CINGULAR) I use a scalar variable ($fh). It does not matter in this small program, but in larger I can take advantage of limiting the scope of the variable so that it doesn't unnecessarily pollute the namespace.
• I tell open to open the file for reading only with the <. Leaving it off means open for read/write, which can be dangerous if overlooked.
• The idiom is open or die instead of the variant with the logical operator || which requires lots of parentheses because it has such a high operator precedence.
• This is probably the most important hint: reading the whole file into an array to process it does not scale well. Once your file gets bigger than your RAM, the operating system must page out to disk and the program will become dog slow. A better approach is to read it line for line and process immediately.

use strict;
use diagnostics;

open my $fh, "<c:/documents and Settings/david price/my documents/cing
+ular.txt" or die "cannot open for reading: $!";
    my $matches;
    while (<$fh>) {
        $matches++ if /9432$/;
        last if $. == 100;
# skip to end of while once we have reached line 100
# $. is a built-in variable, see perlvar in the docs
    };
close $fh;

print "Found $matches matches.\n";
[download]

use strict;
use warnings;

my (@numbers, $handle);

open ($handle, "c:/documents and Settings/david price/my documents/cin
+gular.txt") || die "cannot open: $!";
@numbers = <$handle>;    
close ($handle);

for (@numbers) {
    if (index($_, '9432') != -1) { print "match found\n"; }
    else { print "match failed\n"; }
}
[download]

Line by line analysis of your code is as follows:

open (CINGULAR, "c:/documents and Settings/david price/my documents/ci
+ngular.txt") || die "cannot open: $!";

# USE VARIABLES FOR FILE HANDLES INSTEAD OF NAMED FILE HANDLES

@number=<CINGULAR>;

# DECLARE A SCOPE FOR ALL VARIABLES. my @number=<CINGULAR>; would be b
+etter

close (CINGULAR);
$count=0;

# SAME

while ($count<100) {

# IF YOU WANT TO LOOP THROUGH AN ARRAY, USE SOMETHING LIKE:
# for (my $c = 0; $c <= $#number; $c++) { print $number[$c]; }
# for (0..$#number) { print $number[$_]; }
# for (@number) { print $_; }
# foreach (@number) { print $_; }

# $#number is the address of the last item in the array.
# $_ is the default input / output variable.

    if (@number=~[/^9432$/g]) {

# PROPER SYNTAX IS if ($number[$count] =~ /9432$/) {

# The g flag is used for multiple matches; ^ and $ are only used toget
+her
# if you want a match at both ends - in other words, an exact match.
# I don't know what the brackets were for.

        print "match found"; 
    } else {
        print "match failed";
    }
    $count++;

# THIS IS FINE. HOWEVER, YOU COULD HAVE SAVED A STATEMENT BY DOING:
# while ($count++ < 100) {

}
[download]