in_array and skipping foreach

webchalkboard has asked for the wisdom of the Perl Monks concerning the following question:

Hi Monks,

Just wondering how can I check if a value exists in an array in Perl? Then if it does, just skip to the next element...

In PHP you can use in_array or something, here is how I would write it long-hand in perl, but there must be a more succinct version as there always is in Perl ;) I don't even think this version will work exactly, as I want the 'next' statement to go to the next value in the outer foreach loop, rather than the one it is in.


use Text::CSV_XS;

my $csv = Text::CSV_XS->new({
     'quote_char'  => '"',
     'escape_char' => '"',
     'sep_char'    => ',',
     'binary'      => 1
 });

open FH, "< textfile.txt" or die "Failed to open CSV file for processi
+ng: $!";
my @csv=(<FH>);
close(FH) or die "Failed to close CSV file for processing: $!";

my @ignore_merchants=('merchant 1','merchant 2');

foreach my $line (@csv) {
    if ($csv->parse($line)) {
        my @fields = $csv->fields;

        $offer{retailer}=$fields[0];
        $offer{productid}=$fields[1];

        foreach (@ignore_merchants) {
            # now I want to skip to the next element in the outer loop
+. How can I do that anyway?
            next if ($_ eq $offer{retailer});
        }
}
[download]

Any ideas how I can make this better?

Cheers,
Tom

Learning without thought is labor lost; thought without learning is perilous. - Confucius

WebChalkboard.com | For the love of art...

Comment on in_array and skipping foreach Download Code

Replies are listed 'Best First'.
Re: in_array and skipping foreach by jdporter (Paladin) on Jan 16, 2020 at 16:34 UTC
Any ideas how I can make this better? Any will do it! Specifically, the `any` function from the List::Util module: `use List::Util qw( any ); next if any { $_ eq $offer{retailer} } @ignore_merchants;` [download] Many cases of using grep in a conditional can be written using any instead, as it can short-circuit after the first true result. Of course, a hash is better if you're going to be doing this check a lot of times. I reckon we are the only monastery ever to have a dungeon stuffed with 16,000 zombies.	[reply] [d/l] [select]
Re: in_array and skipping foreach by Joost (Canon) on Apr 13, 2005 at 14:34 UTC
You'll want to use a hash instead: `my %ignore_merchants = map { $_ => 1 } ('merchant 1','merchant 2'); # ... next if $ignore_merchants{$offer{retailer}}; }` [download] "What should it profit a man, if he should win a flame war, yet lose his cool?"	[reply] [d/l]
Re: in_array and skipping foreach by JediWizard (Deacon) on Apr 13, 2005 at 14:34 UTC
First of all: You can use loop labels to controll which loop a `next` or `last` pertains to: `OUTER: foreach my $item (@array){ foreach my $subitem (@array2){ next OUTER if($subitem eq $item); } }` [download] But to actually answer your question: I think it would be better to use `grep` in a scalar context to test for the presence of an item in an array (as opposed to foreach'ing through the array doing an eq comparison). `foreach my $item (@array){ next if(scalar(grep({$_ eq $item} @other_array))); }` [download] see grep, next and last HTH. Cheers Update: As others have suggested, a hash is better for this type of lookup A truely compassionate attitude towards other does not change, even if they behave negatively or hurt you —His Holiness, The Dalai Lama	[reply] [d/l] [select]
Re: in_array and skipping foreach by Random_Walk (Prior) on Apr 13, 2005 at 14:35 UTC
Put the ones to skip into a Hash not an array `my %skip; $skip{$_}++ for qw(skip_me and_me and_this_too); foreach my $line (@csv) { if ($csv->parse($line)) { my @fields = $csv->fields; $offer{retailer}=$fields[0]; next if $skip{$offer{retailer}}; $offer{productid}=$fields[1]; } }` [download] Cheers, R. Pereant, qui ante nos nostra dixerunt!	[reply] [d/l]
Re: in_array and skipping foreach by webchalkboard (Scribe) on Apr 13, 2005 at 14:42 UTC
Doh I feel stupid, and I love hashes :) definately the way to go. Thanks for the info about the next labels too, I will check that out now. Learning without thought is labor lost; thought without learning is perilous. - Confucius WebChalkboard.com \| For the love of art...	[reply]
Re: in_array and skipping foreach by crashulater (Initiate) on Jan 16, 2020 at 16:21 UTC
The hints how to make an in_array() function are already in the various answers. This just puts them together `usage: in_array($needle,@haystack)` returns: 0 if not found and the number of instances found otherwise `sub in_array { my $value = shift(@_) ; my @array = @_ ; return scalar(grep({$_ eq $value} @array)) ; }` [download]	[reply] [d/l] [select]
Re: in_array and skipping foreach by RazorbladeBidet (Friar) on Apr 13, 2005 at 14:31 UTC
There's no specific function for finding a value in an array. You make your own (or use a module). Yours seems fine. For your second question, see next - specifically "next LABEL" -------------- "But what of all those sweet words you spoke in private?" "Oh that's just what we call pillow talk, baby, that's all."	[reply]
Re^2: in_array and skipping foreach by VSarkiss (Monsignor) on Apr 13, 2005 at 14:34 UTC
There's no specific function for finding a value in an array. Eh? What about grep? Seems like it would do just what the OP wanted. Do not rebuke them with harsh words ... but rather lead them gently - with URLs - so that they may learn wisdom.	[reply]
Re^3: in_array and skipping foreach by jbrugger (Parson) on Apr 13, 2005 at 14:43 UTC
Isn't it faster to create a lookuptable next to your array? The value in the array will be the key in the lookup table (hash) with the value 0 or 1. "We all agree on the necessity of compromise. We just can't agree on when it's necessary to compromise." - Larry Wall.	[reply]
Re^4: in_array and skipping foreach by VSarkiss (Monsignor) on Apr 13, 2005 at 14:59 UTC
Re^3: in_array and skipping foreach by RazorbladeBidet (Friar) on Apr 13, 2005 at 14:36 UTC
Ah yes, I spoke to soon. Shouldn't write answers when distracted ;) -------------- "But what of all those sweet words you spoke in private?" "Oh that's just what we call pillow talk, baby, that's all."	[reply]


laziness, impatience, and hubris
	PerlMonks