http://qs1969.pair.com?node_id=473625


in reply to Parsing a macro language

Is there a simple solution to this?

Yes -- as long as your format doesn't have any more complexity that you haven't told us about yet.

There's a general approach to tree-building that's applicable here: Keep a stack of your "active" container, and every time you find a line with a "{" on the end of it, push a new container on to the stack. On lines with a "}", pop the active item off the stack. Every other piece of data that we find can get pushed into whichever container is currently active.

Of course, if your format includes escape characters, multi-line elements, or other complications, you may need to use one of the industrial-strength parser-generators... But for a simple format, we can roll our own.

Take a look at the output of the below, with and without $fewer_indents set true, and modify as desired. 

sub parse_brackets {
  my @parse;
  my @stack = \@parse;
  
  my $fewer_indents = 1;   # Try setting this to 0 or 1
  
  my $line_no;
  foreach my $line ( @_ ) {
    $line_no ++;
    $line =~ s/\A\s+//;
    $line =~ s/\s+\Z//;
    if ( $line !~ /\S/ ) {
      next;
    } elsif ( $line =~ s/\s*\{$// ) {
      my @line = split ' ', $line;
      push @{ $stack[0] }, \@line;
      if ( $fewer_indents ) {
    unshift @stack, \@line;
      } else {
    my @kids = ();
    push @line, \@kids;
    unshift @stack, \@kids;
      }
    } elsif ( $line eq '}' ) {
      shift @stack; 
      scalar @stack or die("Too many right brackets at line $line_no")
+;
    } else {
      push @{ $stack[0] }, $line;
    }
  }

  return @parse;
}

use Data::Dumper;

print Dumper( parse_brackets( split "\n", <<'EXAMPLE' )  );

  page p1 {
      question 4B {
      label {
          Do you like your pie with ice cream?
      }

      single {
          1 Yes
          2 No
      }
      }

      question 4C {
      label {
          Do you like your pie with whipped cream?
      }

      single {
          1 Yes
          2 No
      }
      }
  }

EXAMPLE

[download]

Replies are listed 'Best First'.
Re^2: Parsing a macro language
by simonm (Vicar) on Jul 09, 2005 at 01:20 UTC

    Or, for a hash-based represenation that's closer to what you originally asked for: 

    sub parse_brackets {
  my @parse;
  my @stack = \@parse;
  
  my $fewer_indents = 1;   # Try setting this to 0 or 1
  
  my $line_no;
  foreach my $line ( @_ ) {
    $line_no ++;
    $line =~ s/\A\s+//;
    $line =~ s/\s+\Z//;
    if ( $line !~ /\S/ ) {
      next;
    } elsif ( $line =~ s/\s*\{$// ) {
      my @line = split ' ', $line;
      my %node = ( type => shift(@line), ( @line ? ( name => shift(@li
+ne) ) : () ) );
      push @{ $stack[0] }, \%node;
      unshift @stack, do { $node{contents} = [] };
    } elsif ( $line eq '}' ) {
      shift @stack; 
      scalar @stack or die("Too many right brackets at line $line_no")
+;
    } else {
      push @{ $stack[0] }, $line;
    }
  }
  scalar @stack == 1 or die("Too few right brackets at line $line_no")
+;

  return @parse;
}

    [download]

    Output: 

    $VAR1 = {
          'contents' => [
                          {
                            'contents' => [
                                            {
                                              'contents' => [
                                                              'Do you 
+like your pie with ice cream?'
                                                            ],
                                              'type' => 'label'
                                            },
                                            {
                                              'contents' => [
                                                              '1 Yes',
                                                              '2 No'
                                                            ],
                                              'type' => 'single'
                                            }
                                          ],
                            'name' => '4B',
                            'type' => 'question'
                          },
                          {
                            'contents' => [
                                            {
                                              'contents' => [
                                                              'Do you 
+like your pie with whipped cream?'
                                                            ],
                                              'type' => 'label'
                                            },
                                            {
                                              'contents' => [
                                                              '1 Yes',
                                                              '2 No'
                                                            ],
                                              'type' => 'single'
                                            }
                                          ],
                            'name' => '4C',
                            'type' => 'question'
                          }
                        ],
          'name' => 'p1',
          'type' => 'page'
        };

    [download]

    Oh, and for future reference, I don't think I would call this a "macro language". It's a data markup format, with no functional or substitutional behavior.

[reply]
[d/l]
[select]
      You could decouple the parsing and building steps, as nothingmuch suggested: 
      
sub parse_brackets {
  my @out;
  
  foreach my $line ( @_ ) {
    $line_no ++;
    $line =~ s/\A\s+//;
    $line =~ s/\s+\Z//;
    if ( $line !~ /\S/ ) {
      next;
    } elsif ( $line =~ s/\s*\{$// ) {
      push @out, 'open' => [ split ' ', $line ];
    } elsif ( $line eq '}' ) {
      push @out, 'close' => 1;
    } else {
      push @out, 'line' => $line;
    }
  }
  return @out;
}

sub build_brackets {
  my @parse;
  my @stack = \@parse;
  
  while ( scalar @_ ) {
    my ( $type, $value ) = splice( @_, 0, 2 );
    if ( $type eq 'open' ) {
      my %node = ( type => shift(@$value), ( @$value ? ( name => shift
+(@$value) ) : () ) );
      push @{ $stack[0] }, \%node;
      unshift @stack, do { $node{contents} = [] };
    } elsif ( $type eq 'close' ) {
      shift @stack; 
      scalar @stack or die("Too many right brackets");
    } else {
      push @{ $stack[0] }, $value;
    }
  }
  scalar @stack == 1 or die("Too few right brackets");

  return @parse;
}

use Data::Dumper;

print Dumper( build_brackets( parse_brackets( @lines ) ) );

      [download]

      I'm not sure this is a big win for your case, but if you need the extra flexiblity...

[reply]
[d/l]

In Section Seekers of Perl Wisdom