Interesting challenge to build that with map. The difficulty is that the expansions will need to be somewhat inside-out. Lets try building it one step at a time, outside-in.

Given %properties, we need to work first with its keys, since their names are part of the output. So, my @values = map { foo( $_) } keys %properties; where foo() takes a key of %properties and returns a list of array references taken from that key.

Making an actual sub foo() for that is probably not justified, so we'll expand foo's definition in place,

my @values = map {
    my $key = $_;
    map {
        bar( $key, $_)
    } keys %{$properties{$_}}
} keys %properties;
[download]

In fact, bar() has all the arguments we need, so we expand it again,

my @values = map {
    my $key = $_;
    map {
        [ $key, $_, $properties{$key}{$_}{'value'} ]
    } keys %{$properties{$_}}
} keys %properties;
[download]

That doesn't bother to sort the keys, but if you want that, you can insert it,

my @values = map {
    my $key = $_;
    map {
        [$key, $_, $properties{$key}{$_}{'value'}]
    } sort {$a <=> $b} keys %{$properties{$_}}
} sort keys %properties;
[download]

It's a good idea to avoid one-lining constructions like this. It makes them very hard to read if you skip indentation.