Try this.

#! perl -slw
use strict;

sub modify (\$) {
    our $data;
    local *data = $_[ 0 ];

    $data =~ s[this][that]g;
    return;
}

my $string = 'this & that;' x 10000;

modify $string;

print substr $string, 0, 24;
[download]

I would really drop the our and typeglob usage here. I feel like it's "overkill" for what [id://tomazos] is trying to do.

The following is also an interesting solution, that is quite similar to [id://friedo]'s one, but uses prototype to move referencing backslash from main script into the function code.

#!/usr/bin/perl
use strict;
use warnings;

sub modify (\$) {
    my $string_ref = $_[0];
    $$string_ref =~ s/a/x/g;
}

my $string = 'abc';

print "before `$string'\n"; # abc
modify $string;
print "after  `$string'\n"; # xbc
[download]

Anyway, probably it is best to leave the \ char inside the main script. In this way, it is immediately clear that you're passing a reference, and not the real scalar. In the latter case, you could be tempted to think that a return value is also expected from the modify() function, which actually is not.

Sure, that's using referencing/dereferencing - which is fine, but I'd rather have a normal scalar name ($string rather than $$string_ref).

In this example its trivial, but if you have a lot of variables around, its hard to keep track of whats a reference and whats not.

-Andrew.

---

Andrew Tomazos  |  andrew@tomazos.com  |  www.tomazos.com

sub alter_var {
   my $var_in_sub = $_[0];
   $var_in_sub =~ s/a/b/g;
   $_[0] = $var_in_sub;
}

# or

sub alter_var {
   $_[0] =~ s/a/b/g;
}
[download]

That duplicates the content of $_[0] doesn't it? (Your first example)

I want to pass it by reference, and give it a meaningful identifier in the context of the subroutine. (ie not have to use $_[0] throughout the subroutine.) (Your second example)

-Andrew.

---

Andrew Tomazos  |  andrew@tomazos.com  |  www.tomazos.com

You can use a simple scalar reference, then.

sub alter_var { 
    my $scalar_ref = shift;
    $$scalar_ref =~ s/a/b/;
}

my $scalar = "foobarbaz";
alter_var( \$scalar );
[download]

For more, see perlreftut.

Also note that esskar's second example, which works on $_[0] directly, will alter the scalar passed into the parameter list. (In this case, $_[0] is an alias, not a reference, so there is no need to dereference anything.)

Pardon me for being so dense, but

  DB<1> sub altervar { $_[ 0 ] =~ s/a/b/g }
  DB<2> $var_elsewhere = 'aaa'
  DB<3> altervar( $var_elsewhere )
  DB<4> p $var_elsewhere
bbb
[download]

From the OP's update:

I'd also like to use a meaningful name rather than $_[0] throughout the subroutine.

---

Examine what is said, not who speaks -- Silence betokens consent -- Love the truth but pardon error.

Lingua non convalesco, consenesco et abolesco. -- Rule 1 has a caveat! -- Who broke the cabal?

"Science is about questioning the status quo. Questioning authority".

The "good enough" maybe good enough for the now, and perfection maybe unobtainable, but that should not preclude us from striving for perfection, when time, circumstance or desire allow.