http://qs1969.pair.com?node_id=482002


in reply to Algorithm for cancelling common factors between two lists of multiplicands

Unless the individual values get very large, I think the easiest would be to factor them:

  sub combine_factors {
    my $list = shift;
    my $factors = {};
    for (@$list) {
      for (factors($_)) {
        ++$factors->{$_};
      }
    }
    $factors;
  }

  my $fa = combine_factors(\@a);
  my $fb = combine_factors(\@b);
  ($fa->{$_} ||= 0) -= $fb->{$_} for keys %$fb;
  my @c = map +($_) x $fa->{$_}, grep $fa->{$_} > 0, keys %$fa;
  my @d = map +($_) x -$fa->{$_}, grep $fa->{$_} < 0, keys %$fa;

[download]

This has the disadvantage that it will leave a list of primes: @c == (3, 5, 11), @d == (2, 2, 2, 23). I'm not sure how you'd retain the original composites (or parts thereof), nor how you'd define which composites to keep, so I chose to ignore that aspect of it.

Hugo

Replies are listed 'Best First'.
Re^2: Algorithm for cancelling common factors between two lists of multiplicands
by BrowserUk (Patriarch) on Aug 08, 2005 at 20:20 UTC

    Thankyou hv.

    That'll work. I don't suppose you know of a good factoring algorithm?

    I'd like to avoid Math::Pari (if possible) for this.

    Examine what is said, not who speaks -- Silence betokens consent -- Love the truth but pardon error.
    Lingua non convalesco, consenesco et abolesco. -- Rule 1 has a caveat! -- Who broke the cabal?
    "Science is about questioning the status quo. Questioning authority".
    The "good enough" maybe good enough for the now, and perfection maybe unobtainable, but that should not preclude us from striving for perfection, when time, circumstance or desire allow.
[reply]

      For simple problems I usually use something like this:

      {
  my @p; BEGIN { @p = (2, 3) } 
  sub nextprime { 
    my $p = $p[$#p];
    DIV: while (1) {
      $p += 2; 
      my $pc = 0;
      while (1) { 
        my $d = $p[$pc++];
        last if $d * $d > $p;
        next DIV unless $p % $d;
      }
      $p[@p] = $p; 
      return $p;
    }
  }

  sub factors { 
    my $n = shift;
    my($pc, @result) = (0);
    while ($n > 1) {
      my $d = $p[$pc++] || nextprime();
      if ($d * $d > $n) { 
        push @result, $n;
        $n = 1;
      } else {
        while ($n % $d == 0) {
          $n /= $d;
          push @result, $d;
        }
      }
    }
    \@result;
  }
}

      [download]

      The rest of the time I use Math::Big*, sometimes with Pari or (lately) GMP.

      Hugo

[reply]
[d/l]

        Nice, thankyou. I like nextPrime(). I was kludging something together by embedding the first 1000 primes in a DATA section.

        Examine what is said, not who speaks -- Silence betokens consent -- Love the truth but pardon error.
        Lingua non convalesco, consenesco et abolesco. -- Rule 1 has a caveat! -- Who broke the cabal?
        "Science is about questioning the status quo. Questioning authority".
        The "good enough" maybe good enough for the now, and perfection maybe unobtainable, but that should not preclude us from striving for perfection, when time, circumstance or desire allow.
[reply]
[d/l]
[reply]

In Section Seekers of Perl Wisdom