#!/your/perl/here

use strict;
use warnings;

my @list = qw(apple1 apple apple20);

my @sorted = @list[
    map { unpack "N", substr($_,-4) }
    sort
    map {
        my $key = $list[$_];
        $key =~ s[(\d+)][ pack "N", $1 ]ge;
        $key . pack "N", $_
    } 0..$#list
];

print "@sorted\n";
[download]

apple apple1 apple20
[download]

The whole program is a bit complex and does a bunch of stuff that isn't relavent to this issue, but I've cut out everything but this section that shows the problem I'm having.


#!/usr/bin/perl -w

use strict;

my @h = ( qw(
                psapp1
                psapp
                psapp2
                psepapp1
                psepapp
                psepapp2
                psimgprod
                pspappuat
                pswebapp2
                pswebapp
              ) );

my @h_sorted = @h[
        map { unpack "N", substr($_,-4) }
        sort
        map {
            my $key = $h[$_];
            $key =~ s[(\d+)][ pack "N", $1 ]ge;
            $key . pack "N", $_
        } 0..$#h
];
    

foreach (@h_sorted) { print "$_\n"; };
[download]


When I run this program, with my Perl (This is perl, v5.8.6 built for darwin-thread-multi-2level), I get:

psapp
psapp1
psapp2
psepapp1
psepapp2
psepapp
psimgprod
pspappuat
pswebapp2
pswebapp
[download]

The "psapp" items sort properly, but the "psepapp" and "pswebapp" ones show the problem I'm asking about. Thanks! -s-

Yeah, that's the problem I discussed elsewhere. Here's a simple fix:

#!/usr/bin/perl -w
 
use strict;
 
my @h = ( qw(
                psapp1
                psapp
                psapp2
                psepapp1
                psepapp
                psepapp2
                psimgprod
                pspappuat
                pswebapp2
                pswebapp
              ) );
 
my @h_sorted = @h[
        map { unpack "N", substr($_,-4) }
        sort
        map {
            my $key = $h[$_];
            $key =~ s[(\d+)][ pack "N", $1 ]ge;
            $key . pack "CNN", 0, 0, $_
        } 0..$#h
];

foreach (@h_sorted) { print "$_\n"; };
[download]

This inserts 5 nul bytes which prevents the problem. 1 nul byte is enough to fix this specific case. 4 fixes all cases except for the possibility of "x0" sorting before "x". 5 fixes all cases (provided you don't have nul bytes in your strings).

- tye