#!/usr/bin/perl

use strict;
use warnings;

my $string = 'perl monks';
my $space = qr/\s/;

for (0 .. (length $string) - 2) {
    my $match = substr($string,$_,2);
    next if ($match =~ $space);
    print "$match\n";
}
[download]

Finally, one line, and no experimental features!

sub double_it {
   return join ' ', $_[0] =~ /\w(?=\w(?<=(..)))/g;
}
[download]

Alternate versions:

/\w(?=\w(?<=(..)))/g;
[download]

Isn't that rather more complicated than necessary?

/(?=(\w\w))./g;
[download]

The . is unnecessary.

---

Jeff japhy Pinyan, P.L., P.M., P.O.D, X.S.: Perl, regex, and perl hacker
How can we ever be the sold short or the cheated, we who for every service have long ago been overpaid? ~~ Meister Eckhart

#!/usr/bin/perl

use strict;
use Data::Dumper;

my $string='perl monks';

my @p=grep { m/[a-z]/i } split //,$string;

@p=map { "$p[$_]$p[$_+1]" } 0..$#p-1;

print Dumper \@p;
[download]

Incorrect. It returns
pe er rl lm mo on nk ks
instead of
pe er rl mo on nk ks

my $mystring = "perl monks"; 

# Oops, I thought it was supposed to span words. Thanks for the heads-
+up, kwaping
#(my $splitted = $mystring) =~ s/(?<=.)(\S)\s*(?=\S)/$1 $1/g;
(my $splitted = $mystring) =~ s/(?<=\S)(\S)(?=\S)/$1 $1/g;

print $splitted;
[download]

Sorry Roy, your solution gives lm too.

fix0red!

#!/usr/bin/perl
use strict;
use warnings;

my $string="perl monks"; 
$string =~ s/\s//;
my @splitted_string;
my @chars=split(//, $string);

for ($i=0;$i<=$#chars;$i++) {
    push (@splitted_string, $chars[$i].$chars[$i+1]); 
}

my $splitted_string = join(' ', @splitted_string);
[download]

• Your code doesn't compile due to a strict error.
• Your code gives a warning (once the strict error is fixed).
• Your code doesn't give the right output. (lm shouldn't appear.)

So naturally there is a module that does this: Text::Ngram.

The only thing special about your particular case is that you want to ignore spaces (most bigram analyses of text retain the spaces, because they are meaningful for text analysis). But that's fine -- just do  tr/ //d on your string before you pass it to Text::Ngram.

"perl monks" =~ /(\w{2})(?{print "$1 "})^/;
[download]

my $mystring = "perl monks";

my $tmpstring = $mystring;
my $my_splitted_string = "";
while ($tmpstring)
{
        $tmpstring =~ m/^(\w{2})/ and $my_splitted_string .= $1." ";
        $tmpstring =~ s/^.//;
}

print "$my_splitted_string\n";
[download]

Enjoy,
Mickey

$_ = "perl monks";

#pe er rl mo on nk ks 
for ( split /\s+/ )
{
    $last = "";
    
    for ( split // )
    {
        print "$last$_ " if $last; 
        $last=$_;
    }
}
[download]

$x = "perl monks";
for ( $i=0; $i < length($x)-1; $i++) {
    ($a,$b) = (split//,substr($x,$i,2));
    next if $a eq " " or $b eq " ";
    print "$a$b ";
}
[download]