Take a look at Data::Rmap. You'll be relying upon the uniqueness of your placeholders, but this seems to produce the output your require:

use warnings;
use strict;
use HTML::TreeBuilder;
use Clone qw(clone);
use Data::Rmap qw[rmap_scalar];

my $newHTML =
  ['div', {class => 'ourobject'},
    ['script', {language => 'JavaScript', type => 'text/JavaScript'},
      'embedLabTutorClient("VIEW", "URL", WWW, HHH)',
    ],
    ['noscript',
      ['object',
        {classid=>"CLSID:ReleaseCLSID", width=>'WWW', height=>'HHH', v
+iewastext=>'1'},
        ['param', {name=>'ViewSettingsUrl', value=>'URL'}],
        ['param', {name=>'ViewName', value=>'VIEW'}],
      ]
    ]
  ];


my $objUrl = 'somewhere/object.obj';
my $objView = 'erewhon';
my $objWidth = 255;
my $objHeight = 127;

my $copy = clone ($newHTML);

# Perform 'global' ssubstitutions on $copy here
rmap_scalar{ s/WWW/$objWidth/  } $copy;
rmap_scalar{ s/HHH/$objHeight/ } $copy;
rmap_scalar{ s/VIEW/$objView/  } $copy;
rmap_scalar{ s/URL/$objUrl/    } $copy;

my $element = HTML::Element->new ('root');

$element->push_content ($copy);
print $element->as_HTML(undef, '   ', {});

__END__
c:\test>junk
<root><div class="ourobject">
      <script language="JavaScript" type="text/JavaScript">embedLabTut
+orClient("erewhon", "somewhere/object.obj", 255, 127)</script>
      <noscript>
         <object classid="CLSID:ReleaseCLSID" height=127 viewastext=1 
+width=255>
            <param name="ViewSettingsUrl" value="somewhere/object.obj"
+>
            <param name="ViewName" value="erewhon">
         </object>
      </noscript>
   </div></root>
[download]

Ah, that was the answer I was looking for. Actually ppm didn't find the package among the repositories I use :(. However is did stimulate me in to looking for other similar modules. For that, thank you! :)

In the end I used Data::SearchReplace:

use warnings;
use strict;
use HTML::TreeBuilder;
use Clone qw(clone);
use Data::SearchReplace ('sr');
 
my $newHTML = 
  ['div', {class => 'ourobject'},
    ['script', {language => 'JavaScript', type => 'text/JavaScript'},
      'embedLabTutorClient("VIEW", "URL", WWW, HHH)',
    ],
    ['noscript',
      ['object',
        {classid=>"CLSID:ReleaseCLSID", width=>'WWW', height=>'HHH', v
+iewastext=>'1'},
        ['param', {name=>'ViewSettingsUrl', value=>'URL'}],
        ['param', {name=>'ViewName', value=>'VIEW'}],
      ]
    ]
  ];


my $objUrl = 'somewhere/object.obj';
my $objView = 'erewhon';
my $objWidth = 255;
my $objHeight = 127;

my $copy = clone ($newHTML);

sr {SEARCH => 'WWW', REPLACE => $objWidth}, $copy;
sr {SEARCH => 'HHH', REPLACE => $objHeight}, $copy;
sr {SEARCH => 'VIEW', REPLACE => $objView}, $copy;
sr {SEARCH => 'URL', REPLACE => $objUrl}, $copy;
    
my $element = HTML::Element->new ('root');

$element->push_content ($copy);
print $element->as_HTML(undef, '   ', {});
[download]

Prints:

<root><div class="ourobject">
      <script language="JavaScript" type="text/JavaScript">embedLabTut
+orClient("erewhon", "somewhere/object.obj", 255, 127)</script>
      <noscript>
         <object classid="CLSID:ReleaseCLSID" height=127 viewastext=1 
+width=255>
            <param name="ViewSettingsUrl" value="somewhere/object.obj"
+>
            <param name="ViewName" value="erewhon">
         </object>
      </noscript>
   </div></root>
[download]

---

DWIM is Perl's answer to Gödel

You have a solution, but actually, Data::Rmap is pure perl, consisting of a single .PM file. There is really no need to seek a binary distribution. As a minimal installation, just downloading and installing that one file into your site/lib tree will suffice.

The reason it fails the AS auto-build process is it's dependancy upon Test::Exception. I commented out the 6 tests that use that--they simple check that it handles attempts to modify read-only arguments, and the rest of the tests pass fine.

---

Examine what is said, not who speaks -- Silence betokens consent -- Love the truth but pardon error.

Lingua non convalesco, consenesco et abolesco. -- Rule 1 has a caveat! -- Who broke the cabal?

"Science is about questioning the status quo. Questioning authority".

In the absence of evidence, opinion is indistinguishable from prejudice.

I can manualy access each string that needs to be fixed by navigating the template structure, but that is somewhat fragile. Is there a better way of doing this?

Or you could naviate your datastructure, since the structure seems well defined.

Or use look_down (and friends) to recurse through your $element, and do replacements where appropriate.

Three possibilities off the top of my head.

First, do your substitutions on the string returned from as_HTML. A little error-prone, but probably not that bad.

Second, stop using HTML::Element. Use HTML::Template instead. You could put the template in your __DATA__ section.

Third, use Template Toolkit - instead of having WWW and HHH, etc., have [%WWW%] and [%HHH%], etc. And then you can feed the as_HTML output into Template Toolkit to do the next level of modification. You can't easily do this with HTML::Template only because having <tmpl_var name="HHH"> instead of just HHH would get modified by HTML::Element to look like &lt;tmpl_var name="HHH"&gt; inside the tags, and that would defeat it. TT2 could handle that largely because it uses different delimiters.

I realise that you are probably looking for a way to traverse the data structure. That's just not the way I'm looking at the problem - I have a different box to think inside of ;-}

This is in the context of code that is editing existing HTML to replace object elements with a chunk of script.

Option 1 simply won't work because many parameters need to be replaced with different values in different contexts.

Options 2 and 3 probably don't make sense in this context. XML::Twig would be great, but XHTML these pages are not!

Currently I'm doing it by navigating the structure, but that is rather fragile!

---

DWIM is Perl's answer to Gödel

Cheers,
Matt