http://qs1969.pair.com?node_id=55271


in reply to namespace craziness

After being surprised by the output, I realized that this really isn't a namespace issue at all. Rather, it's a compile time/runtime issue.

Both use constant statements are executed at compile time, but the assignment to $x doesn't happen until runtime. When the second use constant is executed, $x is not yet defined, so Second::MULTIPLIER gets the value 2.

At runtime, $x is assigned the value of MULTIPLER in the First package, which is 25, and then multiplied by the value of MULTIPLIER in the Second package, which is 2.

Try this variation, where $x is assigned at compile time: 

#!/usr/bin/perl -w
use strict;

package First;
use constant MULTIPLIER => 5*5;
my $x;

BEGIN {$x = MULTIPLIER};

package Second;
use constant MULTIPLIER => defined $x ? First::MULTIPLIER : 2;
print MULTIPLIER * $x, "\n";

[download]

Replies are listed 'Best First'.
Re: Re: namespace craziness
by mkmcconn (Chaplain) on Jan 30, 2001 at 22:02 UTC

    Great catch, chipmunk! I see that it is a compile-time issue in the assignment of a value to the constant. Yet, in which namespace is that assignment to $x happening? It's not in "package First" - the $x in the BEGIN block is a global (note no need for use vars: readers could try testing for defined $First::x in the ternary to see what I mean.

    What fun! so, let's turn this into a compounded namespace+compile-time (follow the $x) problem, by re-writing the puzzle like this : 

    #!/usr/bin/perl -w
# version chipmunk * .04
use strict;

package First;
use constant MULTIPLIER => 5*5;
my $x = MULTIPLIER / 25;

BEGIN {$x = MULTIPLIER};

package Second;
use constant MULTIPLIER => defined $x ? First::MULTIPLIER : 2;
print MULTIPLIER * $x, "\n";
  # now what will it print?
__END__

    [download]

    Update
    more good points, chipmunk. I think that each element is a red-herring: the special effects of use constant;, my(), and package in these snippets, all highlight how important it is to understand the context of what's happening in the program, where and when. Thanks for your help in thinking through the issues further.
    mkmcconn

[reply]
[d/l]
      $x was declared with my, so it is a lexical variable and not in any namespace/package. The package declarations are really a red herring in this code. Compare these similar scripts: 
      #!/usr/bin/perl -w

use strict;

use constant FIRST => 25;

my $x = FIRST;

use constant SECOND => defined $x ? FIRST : 2;

print SECOND * $x, "\n";

__END__

      [download]
      #!/usr/bin/perl -w

use strict;

use constant FIRST => 25;

my $x ;

BEGIN { $x = FIRST; }

use constant SECOND => defined $x ? FIRST : 2;

print SECOND * $x, "\n";

__END__

      [download]
[reply]
[d/l]
[select]

In Section Meditations