How many times do we have to tell the children? Do not hand roll code to parse HTML/XML, life just ain't long enough for that to be worth while - even as an exercise.

Use HTML::TreeBuilder for HTML or XML::Twig for XML. In this case it looks like XML so lets wrap a root element around the sample data provided and see what we can do:

use strict;
use warnings;
use XML::Twig;

my $xml = <<XML;
<root>
[download]

</root>
XML

my $t= XML::Twig->new (twig_roots => {emp => \&emp, prod => \&prod});
my %emp;
my $currEmp;

$t->parse ($xml);

print "$_ - $emp{$_}\n" for sort keys %emp;


sub emp {
    my ($t, $data) = @_;
   
    $currEmp = $data->trimmed_text ();
    $emp{$currEmp} ||= '';
}


sub prod {
    my ($t, $data) = @_;
    my $text = $data->trimmed_text ();
    
    return if $text !~ /^\d+(\.\d*)?/;
    $emp{$currEmp} ||= 0;
    $emp{$currEmp} += $text;
}
[download]

Prints:

3017 - 
3123 - 96.21127
3192 - 
3379 - 6.66666666666667
3384 - 114.285714285714
3417 - 11.4285714285714
[download]

I, for one, often like to find the solutions that don't involve modules. As a fairly new coder, I am not confident in their use. Additionally, I think that many of the solutions that can be solved without the use of a module are enhancing my understanding of how perl works.

On the other hand, learning something about modules is helpful as well... and helping everyone learn is what this site is supposed to be about.

All problems that can be solved using a module (written by someone else) can be solved without using the module. It's just that you may end up rewriting the module! Redoing hundred or thousands of hours of work may be a good way of learning, but it doesn't get the task at hand achieved in a timely fashion.

Of course if you really want to learn stuff try solving the same problems in assembly language or Ook! - you'll learn all sorts of stuff about frustration and low productivity, but those are probably not the things you want to learn.

One of the important lessons to learn here is that there are a lot of very clever people writing modules for Perl and making them freely available. Using those modules can save you a lot of time. Peeking at the internals of those modules can teach you a lot about coding techniques. Using modules you can win both ways - learning and saving time.

---

DWIM is Perl's answer to Gödel

I, for one, often like to find the solutions that don't involve modules. As a fairly new coder, I am not confident in their use.

That attitude can be a little bit dangerous. If you have a chance, skim the XML 1.0 specification. I'm certainly not going to hand-roll code to parse XML in a couple of hours, and I'm a fairly experienced coder.

You're a lot better off spending your learning time figuring out how to take advantage of work other people have already done. This particular case is awfully complex.

hi

Thank you very much!! Your code is amazing. I just need one further help. I have the contents <act>key</act>... on a separate xml file. I am not able to succeed if I use open or if I store the file to a variable and call the variable from the place where you have placed the content. Can you please tell me how I can call a external file here?

Thanks, for all your help in this

It's not clear to me what you are trying to achieve with the separate file. Perhaps you could sketch in code what you are trying to do? Not a fully worked attempt to provide a solution to the problem, but an outline of the steps you think are required.

---

DWIM is Perl's answer to Gödel

You are assuming you already have a list @inlst of employees, though your code doesn't show where it comes from. The program should probably build the list as it goes along.

Here is one way to do it (__DATA__ section not shown):

use List::Util qw( sum);

my (@emp_lst, %prod);
while ( <DATA> ) {
    my ( $emp) = m{<emp>(\d+)</emp>} or
        warn "No <emp> in line $.\n", next;
    push @emp_lst, $emp unless $prod{ $emp};
    $prod{ $emp} ||= [];
    my ( $prod) = m{<prod>([.\d]+)</prod>} or next;
    push @{ $prod{ $emp} }, $prod;
}
for ( values %prod ) {
    $_ = @$_ ? sum( @$_)/@$_ : '';
}
print "$_ - $prod{ $_}\n" for @emp_lst;
[download]

Update: I agree with GrandFather that an appropriate parser is a better solution.

Update: Noticed an optimisation. The pesky $prod{ $emp} ||= []; can go from the while loop and everything rely on autovivification as it should:

while ( <DATA> ) {
    my ( $emp) = m{<emp>(\d+)</emp>} or
        warn "No <emp> in line $.\n", next;
    push @emp_lst, $emp unless $prod{ $emp};
    push @{ $prod{ $emp} }, m{<prod>([.\d]+)</prod>};
}
[download]