First of all, when I run your program, I get errors:

syntax error at validate.pl line 29, near "() "
syntax error at validate.pl line 35, near "}"
Execution of validate.pl aborted due to compilation errors.
[download]

But I also recommend you get in the habit of using strict in your programs (you are already using -w, to turn on warnings, which is good):

#!/usr/local/bin/perl -w

use strict;
use warnings;    # Already on with -w, but doesn't hurt to be explicit

#
# Version 0.1
#
[download]

At which point you will get a couple dozen warnings:

Variable "$log_file" is not imported at validate.pl line 25.
Variable "$spec_file" is not imported at validate.pl line 26.
Variable "$data_in_file" is not imported at validate.pl line 27.
Variable "$data_out_file" is not imported at validate.pl line 28.
Variable "$spec_file" is not imported at validate.pl line 29.
Variable "$data_in_file" is not imported at validate.pl line 29.
Variable "$data_out_file" is not imported at validate.pl line 30.
Variable "$log_file" is not imported at validate.pl line 30.
Global symbol "$spec_file" requires explicit package name at validate.
+pl line 24.
Global symbol "$data_in_file" requires explicit package name at valida
+te.pl line 24.
Global symbol "$data_out_file" requires explicit package name at valid
+ate.pl line 24.
Global symbol "$log_file" requires explicit package name at validate.p
+l line 24.
Global symbol "$max_errors" requires explicit package name at validate
+.pl line 24.
Global symbol "$log_file" requires explicit package name at validate.p
+l line 25.
Global symbol "$log_file" requires explicit package name at validate.p
+l line 25.
Global symbol "$spec_file" requires explicit package name at validate.
+pl line 26.
Global symbol "$spec_file" requires explicit package name at validate.
+pl line 26.
Global symbol "$data_in_file" requires explicit package name at valida
+te.pl line 27.
Global symbol "$data_in_file" requires explicit package name at valida
+te.pl line 27.
Global symbol "$data_out_file" requires explicit package name at valid
+ate.pl line 28.
Global symbol "$data_out_file" requires explicit package name at valid
+ate.pl line 28.
Global symbol "$spec_file" requires explicit package name at validate.
+pl line 29.
Global symbol "$data_in_file" requires explicit package name at valida
+te.pl line 29.
Global symbol "$data_out_file" requires explicit package name at valid
+ate.pl line 30.
Global symbol "$log_file" requires explicit package name at validate.p
+l line 30.
Global symbol "$max_errors" requires explicit package name at validate
+.pl line 30.
Global symbol "$spec_line" requires explicit package name at validate.
+pl line 32.
syntax error at validate.pl line 32, near "() "
validate.pl has too many errors.
[download]

It appears that almost all of the errors in your program are caused by not declaring your variables.  In many cases this is easily fixed by using my to declare the variable.  For example:

my ($spec_file, $data_in_file, $data_out_file, $log_file, $max_errors)
+ = @ARGV;
[download]

which will get rid of many of the errors.

In a few cases, you may have to declare the offending variable globally, in order to have it remain in scope everywhere it's used.  One such example is @spec_all_attributes; the first time you use it is within a foreach loop, so you should declare @spec_all_attributes before that loop.

When you open a file, you can avoid the warnings by doing this:

# Note that you don't have to put quotes "..." around $spec_file
open ($spec_file, $spec_file) or die "Can not open file $spec_file, $!
+";
[download]

It's considered good practice to use the 3-argument form of open -- for example:

open ($log_file, ">", $log_file) or die "Can not open file $log_file, 
+$!";
[download]

Addionally, you might consider giving a syntax message if the number of command-line arguments isn't what's expected.  This isn't always just for others who use your program; you may come back to it months or years later, and wonder what the calling syntax was supposed to be.  For example, I'd be inclined to do something like the following:

my $syntax = "
    syntax:  $0  <specfile> <data_in> <data_out> <logfile> <max errors
+>

    The purpose of this program is ...

";

(my $spec_file     = shift) or die $syntax;
(my $data_in_file  = shift) or die $syntax;
(my $data_out_file = shift) or die $syntax;
# etc...
[download]

One final comment on the style -- it's usually considered unnecessary "noise" in a program to use comments which are obvious.  The classic example is:

$i++;   # Increment $i (duh!)
[download]

So you may want to lighten up a little on comments which don't add anything, and as your comments make the code very hard to read (at least for me), you may want to rethink your commenting style.  Try putting comments on their own lines (rather than making lines longer than 80 characters even more long), and add some whitespace where it helps the readability.

Thus, I'd suggest, instead of:

foreach my $attribute (@data_in_attributes) {
if ($attribute =~ m/$spec_all_attributes[$attribute_position][1]/) { #
+ validate data attribute type by performing 
  # lookup for the regular expression from the spec memory structure
  push (@data_out_attributes, $attribute); # Correct data type, the ou
+tput value is same as input value
} else {
  push (@data_out_attributes, $spec_all_attributes[$attribute_position
+][2]); 
    # Bad data type, use default provided in the spec for output value
  $total_errors++;
  print log_file "Error ", $total_errors, ". Data type error on line: 
+", $line_number, 
    ", attribute: ", $attribute_position + 1, " (", $spec_all_attribut
+es[$attribute_position][0], ")\n";
}
last DATALINE if ($total_errors >= $max_errors); # terminate if too ma
+ny errors
$attribute_position++;
}
[download]

that something like the following may be a lot easier to read:

foreach my $attribute (@data_in_attributes) {
    # validate data attribute type by performing 
    # lookup for the regular expression from the spec memory structure

    if ($attribute =~ m/$spec_all_attributes[$attribute_position][1]/)
+ {
        # Correct data type, the output value is same as input value
        push @data_out_attributes, $attribute;
    } else {
        # Bad data type, use default provided in the spec for output v
+alue
        push @data_out_attributes, $spec_all_attributes[$attribute_pos
+ition][2]; 
        $total_errors++;
        print log_file "Error ", $total_errors,
            ". Data type error on line: ", $line_number, 
            ", attribute: ", $attribute_position + 1,
            " (", $spec_all_attributes[$attribute_position][0], ")\n";
    }

    # terminate if too many errors (<-- but perhaps this is obvious??)
    last DATALINE if ($total_errors >= $max_errors);
    $attribute_position++;
}
[download]

(my $spec_file     = shift) or die $syntax;
(my $data_in_file  = shift) or die $syntax;
(my $data_out_file = shift) or die $syntax;
# etc...
[download]

Yuk!

die $syntax unless @ARGV == 5;
my ($spec_file, $data_in_file, $data_out_file, $log_file, $max_errors)
+ = @ARGV;
[download]

or

my ($spec_file, $data_in_file, $data_out_file, $log_file, $max_errors)
+ = @ARGV;
die $syntax unless defined $max_errors;
[download]

Do not repeat yourself!

use warnings; # Already on with -w, but doesn't hurt to be explicit

How is -w less explicit than use warnings;, as far as enabling warning is concerned?

---

Open source softwares? Share and enjoy. Make profit from them if you can. Yet, share and enjoy!

Maybe it's just me; I feel like it's more explicit when I see it together with strict, spelled out:

use strict;
use warnings;
[download]

But I confess that I still don't trust -w on Windows (even though I now know it works perfectly well), because Windows ignores the first part of the shebang line.  To test this, you can do:

#!/usr/path/which/does/not/exist/perl
[download]

and it'll still run Perl correctly.  Granted this isn't a reason to stop using -w, which still does work as I mentioned, but it did make me suspicious of the whole top line for quite a while.

---

s''(q.S:$/9=(T1';s;(..)(..);$..=substr+crypt($1,$2),2,3;eg;print$..$/

I did figure out why you were getting those syntax errors, if you copy the code from dwoptimize. The blogger was eating some of the < and > characters even with the html "code" tag defined. Fixed now.

#!/usr/local/bin/perl -w
use strict;
#
# http://www.dwoptimize.com/2007/05/data-type-validation-using-regular
+.html
# jag.singh@dwoptimize.com
# Version 0.2 
#   feedback incorporated from http://www.perlmonks.org/?node_id=61769
+2
#
my $syntax = ">
> Syntax: $0 <spec_file> <data_in_file> <data_out_file> <log_file> <ma
+x_errors>
>
> This program:
>
> 1. Reads specification file that defines the data file layout:
> 1.1. attribute name
> 1.2. attribute data type using regular expressions 
>      (http://www.perl.com/pub/a/2000/11/begperl3.html)
> 1.3. default data value 
>
> 2. Validates input data file for data type
>
> 3. Creates output data file, with bad attribute data values that do 
+not match
>    specifiction replaced by the default values
>
> 4. Creates a log file describing data validation errors
>
> 5. Aborts data validation process, if total number of errors reach m
+ax_errors
>
> Terminating... ";
#
my ($spec_file, $data_in_file, $data_out_file, $log_file, $max_errors)
+ = @ARGV;
die $syntax, "not all the required command line parameters are provide
+d" 
  unless defined $max_errors;
open (log_file, ">", $log_file) or die $syntax, 
  "cannot open ", $log_file, ". ", $!;
open (spec_file, $spec_file) or die $syntax, 
  "cannot open ", $spec_file, ". ", $!;
open (data_in_file, $data_in_file) or die $syntax, 
  "cannot open ", $data_in_file, ". ", $!;
open (data_out_file, ">", $data_out_file) or die $syntax, 
  "cannot open ", $data_out_file, ". ", $!;
print log_file "Spec File> ", $spec_file, "\n", 
  "Data In File> ", $data_in_file, "\n", 
  "Data Out File> ", $data_out_file, "\n", 
  "Log File> ", $log_file, "\n", 
  "Max errors: ", $max_errors, "\n";
#
my $spec_line; my @spec_one_attribute; my @spec_all_attributes; 
foreach $spec_line (<spec_file>) { 
  # Read full data file specification into memory structure from the s
+pec file
  # which will be used for "lookup" during data validation later
  chomp ($spec_line); # remove newline
  @spec_one_attribute = split(/\,/, $spec_line); 
    # the spec file is ',' delimited
    # @spec_one_attribute contains: attribute name, 
    # attribute data type (regular expression), and default value
  push (@spec_all_attributes, [@spec_one_attribute]); 
    # @spec_all_attributes contain the full data file specification
}
#
my $data_in_line; my @data_in_attributes; my $line_number = 1; 
my $total_errors = 0;
DATALINE: foreach $data_in_line (<data_in_file>) { 
  # read data file, line by line
  chomp ($data_in_line); # remove newline
  @data_in_attributes = split (/\|/, $data_in_line); 
    # the data file is '|' delimited
  if ($#data_in_attributes != $#spec_all_attributes) { 
    # number of attributes on the data line do not match with the spec
+ification
    $total_errors++;
    print log_file "Error ", $total_errors, ". On the data line: ", 
      $line_number, ", # attributes: ", $#data_in_attributes + 1, 
      ", do not match # attributes in the file specification: ", 
      $#spec_all_attributes + 1, "\n";
    last DATALINE if ($total_errors >= $max_errors); 
    next; # skip data attribute type validation
  }      
  my $attribute; my $attribute_position = 0; my @data_out_attributes =
+ ();
  foreach $attribute (@data_in_attributes) {
    if ($attribute =~ m/$spec_all_attributes[$attribute_position][1]/)
+ { 
      # validate data attribute type by performing 
      # lookup for the regular expression from the spec memory structu
+re
      push (@data_out_attributes, $attribute); 
        # Correct data type, the output value is same as input value
    } else {
      push (@data_out_attributes, $spec_all_attributes[$attribute_posi
+tion][2]); 
        # Bad data type, use default provided in the spec for output v
+alue
      $total_errors++;
      print log_file "Error ", $total_errors, 
        ". Data type error on line: ", $line_number, ", 
        attribute: ", $attribute_position + 1, 
        " (", $spec_all_attributes[$attribute_position][0], ")\n";
    }
    last DATALINE if ($total_errors >= $max_errors); 
    $attribute_position++;
  }
  print data_out_file join ("|", @data_out_attributes), "\n"; 
    # the data out file is '|' delimited
} continue { 
  # update line number counter even if the data attribute type 
  # validation is skipped
  $line_number++;
}
#
if ($total_errors >= $max_errors) {
  print log_file "Max error count reached: ", $total_errors, ", proces
+s terminated\n";
} else {
  print log_file "Process completed with: ", $total_errors, " errors\n
+";
}
# End
[download]