my $found= 0;
while(  <>  ) {
    if(  0 == $found  &&  /^From: "\Q$Name\E"/  ) {
        $found++;
    } elsif(  1 == $found  &&  /^To: <sip:$Number@/  ) {
        $found++;
    } elsif(  2 == $found  &&  /^Call-ID: (.*)/  ) {
        return $1;
    } elsif(  /^From: /  ||  /^$/  ) {
        $found= 0;
    }
}
[download]

I got your expression to work on your test data with a couple of small changes, but if you have a huge file full of that stuff, you probably want something a little different. In particular, you want to keep .* from matching more than one record at once. Here's what I came up with:

use strict;
use warnings;

$_ = <<'END_SIP_LOG';
From: "Bungalo Bill" <sip:5555555555@11.11.11.111:22>;tag=SD223sd2-312
+33dss^M
To: <sip:6666666666@11.11.11.111:22>^M
Call-ID: SD0e1af02-4d8d3eesdfsdfsd44w5f6fdb77814d-h6030fd^M
END_SIP_LOG
    ;
s/\^M/\r/g;

my $NAME = 'Bungalo Bill';
my $INBOUND_NUMBER = '6666666666';

#my ($callid) = /From.*$NAME.*$INBOUND_NUMBER.*Call-ID:\s(.*)/s;

my ($callid) = m{ From:    \s "\Q$NAME\E"                  .*? \r \n?
                  To:      \s <sip: \Q$INBOUND_NUMBER\E \@ .*? \r \n?
                  Call-ID: \s (\S+)                        .*? \r \n?
             }xms;

print "callid = '$callid'\n";
__END__
callid = 'SD0e1af02-4d8d3eesdfsdfsd44w5f6fdb77814d-h6030fd'
[download]

I'm not sure if you have straight \r as line endings or the more likely \r\n, so the pattern matches either one.

Updated to format the pattern prettier.

/.*?/s isn't enough to prevent that part of the regex from gobbling up multiple lines and also backtracking pathologically. For example, your regex will incorrectly match (after you fix \r \n? to \r? \n or just \n):

From: "Bungalo Bill" ...
To: (wrong number)
Call-ID: (wrong call)
...
From: "Wrong Person" ...
To: <sip:66666­66666@...>
Call-ID: ThisIsTheWrongCallID
[download]

- tye        

Good catch! If lines do end in \n, the fix is easy. Just remove the /s option. Then /./ won't match the newline. The .* parts match to the end of the line (as they're supposed to) and won't go any further. If lines are terminated in \r, I'd have to change .* to [^\r]* instead.

Update: Net::SIP won't help you -- it doesn't parse logs. Thanks for the heads-up Corion.

/^From:\s*"\Q$NAME\E".*$ \s*
 ^To:\s*<sip:\Q$INBOUND_NUMBER\E@.*$ \s*
 ^Call-ID:\s*(.*)/mgx
[download]

And the idea behind:

• Use ^, $ and //m as line delimiter - we search for three lines: /^something$ \s* ^something2$ \s* ^something3$/m. That assures the regexp will match nearest three lines and not first, second and 300th line. I don't understand why after $ and before ^ regexp must have \s* to catch any newline characters (notice that you don't have to worry which system you are working on, which line delimiters you have, just \s*). It seems $ matches the place right before newline character.
• Now that three parts of regexp are limited to single line (I like that limitation and try to achieve it every time to avoid //s), let's limit variables: I suggest to limit $NAME by "" and $INBOUND_NUMBER by 'sip:' and '@'. That will assure regexp won't match on $NAME="Kevin Black" when there is 'From: "Kevin Blackwood"'