my @array = qw( your array here );
my $search_for = "here";
my( $index )= grep { $array[$_] eq $search_for } 0..$#array;
[download]

Sorry, merlyn. Perhaps you meant:

my ($index) = grep $array[$_] eq $search_for, 0 .. $#array;
[download]



japhy -- Perl and Regex Hacker

grep $array$_ eq $search_for, 0 .. $#array; will return matched array which stores the index of the matching words. my @index_arr = grep {$array$_ eq $search_for} 0 .. $#array; or my @index_arr = grep $array$_ eq $search_for, 0 .. $#array; foreach (@index_arr) { print "matching position = $_\n"; }

Yeah, typed too fast. :)

-- Randal L. Schwartz, Perl hacker

Newbie question: I am very new to Perl and am a little confused about grep here.

my ($index) = grep $array[$_] eq $search_for, 0 .. $#array;

This is what I think is happening: grep is stepping through the range of numbers in list 0..$#array and substituting each in $_, and then using this as an index to find the corresponding element in @array. Eventually the expression $array[$_]eq $search_for is true and that element of the range 0..$#array is put into a list returned by grep, which is then assigned to ($index).

This is my area of confusion: If @array has duplicate values, why does grep seem to stop when it finds the first value rather than produce a list of two values? Yet if I replace ($list) with @list, I get the index of both duplicate elements. I would greatly appreciate it if someone could cast some light on my darkness here :)

I've got it! I think - this is a list, not an array, and according to Perlfaq4.pod (I know, I know, but I was looking under "grep") you can't push/pop a list as you can an array. This is also explained very well in the Perl Journal at http://www.tpj.com/articles/2001/0101/0101a/0101a.htm

my @a = ( 1 .. 1_000_000 ); # some large array

my $want = 5843;
my $index = 0;
++$index until $a[$index] == $want or $index > $#a;
[download]

The last line should be ++$index until $a[$index] == $want or $want > $#a, and thanks to stephen for pointing this out.

my @array = qw( your array here );
my $search = "array";

my %index;
@index{@array} = (0..$#array);
my $index = $index{$search};
print $index, "\n";
[download]

Using merlyn's example with regular expressions, so you don't need to know the exact value of the element you are matching;

my @array = ( 'Name: Mr. Jones', 
              'Phone: 555-555', 
              'Email: jones@example.com' 
);
my ( $index )= grep { $array[$_] =~ /Phone/ } 0..$#array;
[download]

use List::MoreUtils;

my @array = qw( Apples Oranges Brains Toes Kiwi);
my $search = "Toes";

my $index = List::MoreUtils::first_index {$_ eq $search} @array;

print "index of $search = $index\n";
[download]

 
my @array = qw( your large, sorted array here );
my $search = "thing";
my $index = bsearch(\@array, $search);

sub bsearch {
    my ($array, $word) = @_;
    my $low = 0;
    my $high = @$array - 1;

    while ( $low <= $high ) {
        my $try = int( ($low+$high) / 2 );
        $low  = $try+1, next if $array->[$try] lt $word;
        $high = $try-1, next if $array->[$try] gt $word;
        return $try;
    }
    return;
}
[download]

use List::Util qw(first);

my @array = qw( Apples Oranges Brains Toes Kiwi);
my $search = "Toes";

my $index = first { $array[$_] eq $search } 0 .. $#array;

print "index of $search = $index\n";
[download]

my @a = ( .. some extremely huge array .. );
my @want = ( .. some array of things I want to find )

my $index_a = make_indexfinder(\a);

foreach ( @want ) {
    print $index_a->($want), "\n";
}

sub make_indexfinder {
    my ($arrayref) = @_;

    my %value_table = ();
    my $last_index = 0;

    return sub {
        my ($quarry) = @_;

        exists $value_table{$quarry} and return $value_table{$quarry};

        for ($last_index .. $#$arrayref) {
            ($quarry eq $arrayref->[$_]) and do {
                $last_index = $_;
                $value_table{ $quarry } = $_;
                return $_;
            };
            $value_table{ $arrayref->[$_] } = $_;
        }
        return undef;
    };
}
[download]

Originally posted as a Categorized Answer.

@array = (...some 1_000_000 element array...);
$search_for = "blah";

my $index = 0;
while ( $array[$index] != $search_for ) { $index++ }
[download]

Originally posted as a Categorized Answer.

I also was looking for a method to do this, preferably the fastest possible. With a relatively small array (256), the use List::Util qw(first); method was actually significantly slower than simply iterating through the array and breaking(last) out once the match was found. In my test example on a 2.5MB file doing a sort of Sbox type lookup, the iterating took about 3m45s on my old Atom netbook where as the use List::Util qw(first); method required over 5m. Does anyone know the fastest way to perform these index lookups? A few of the examples shown appear to be basically identical. Hashing an array(did I say that right?) is a concept I am not yet familiar with.

Originally posted as a Categorized Answer.

You should use first() from List::Util. List::Util is a core module, unlike List::MoreUtils and other modules mentioned above, so it is portable and can be used with no extra effort.

use List::Utils qw(first);

my @array = qw( Apples Oranges Brains Toes Kiwi);
my $search = "Toes";

my $index = first {$_ eq $search} @array;

print "index of $search = $index\n";
[download]

I meant

use List::Utils qw(first);
my @array = qw( Apples Oranges Brains Toes Kiwi);
my $search = "Toes";
my $index = first {$array[$_] eq $search} 0..$#array;
print "index of $search = $index\n";
[download]